有值的空白单元格

Question

我的书中有很多没有任何价值但仍计入“计数”的单元格。当我尝试使用 Ctrl 和箭头键导航时，这些单元格也会“中断”滚动，这很烦人。当我选择这些单元格并删除它们时，它们不再具有“值”（如果我编辑文本并在每个单元格上按 Enter 键也可以使用），但它是一个大小适中的文档，其中包含很多。我想知道是什么原因，是否有办法解决它。

“计数：14”在空单元格中：

Answer 1

工作表的UsedRange 属性还包括您看到的带有幻影数据的单元格，这可以帮助您动态清除正确的单元格。请注意，这将清除空白单元格中的所有内容。这包括 cmets、格式化等，因此请确保对于没有幻影数据问题的其他单元格来说这不是问题。

1. 遍历UsedRange 中的每个单元格并查找带有Len = 0 和HasFormula = False 的单元格，即要清除的空白
2. 将这些单元格（无字符）添加到Union （单元格集合）
3. 循环完成后，清除Union，这有望解决您的问题

---

Sub Clear()

Dim Target As Range
Dim ClearMe As Range

For Each Target In Sheets("Sheet1").UsedRange
    If Len(Target) = 0 And Not Target.HasFormula Then
        If Not ClearMe Is Nothing Then
            Set ClearMe = Union(ClearMe, Target)
        Else
            Set ClearMe = Target
        End If
    End If
Next Target

If Not ClearMe Is Nothing Then ClearMe.Clear

End Sub

---

如果您想在整个工作表上运行宏之前对此进行测试，请将UsedRange 替换为您在照片中向我们展示的实际范围。例如，For Each Target In Sheets("Sheet1").Range("A1:A10")（idk 实际范围）。宏完成后，查看同一范围是否在突出显示后显示计数

Answer 2

如果单元格 A2 显示为空，并且 A2 的长度为零，则在另一个单元格中输入：

=IF(LEN(A2)<>0,"stuff",IF(COUNTA(A2)=0,"genuine empty","null character"))

这将使您能够区分：

1. 单元格中的字符
2. 单元格中什么都没有
3. 在单元格中返回 Null 的公式或 Null 常量
   （我指的是 零长度字符串 )

如果你想Clear这些单​​元格，运行这个简短的宏：

Sub diogo()
    Dim cell As Range, wf As WorksheetFunction
    Set wf = Application.WorksheetFunction
    For Each cell In ActiveSheet.UsedRange
        If Len(cell.Value) = 0 Then
            If wf.CountA(cell) = 1 Then
                cell.Clear
            End If
        End If
    Next cell
End Sub