循环浏览行以匹配不同工作表上的两个单元格

Question

我正在寻找循环浏览工作表 1 的列中的每一行，以匹配两个单元格（工作表 1 的 C 列中的一个单元格与工作表 2 的 E 列中的一个单元格）。

如果有匹配，我想对相邻的单元格执行一个操作（我稍后会解决这个问题），然后继续循环，直到没有更多匹配为止。

到目前为止，我有以下内容：

Sub Test3()
    Dim x As String
    Dim found As Boolean
    ' Select first line of data.
    Worksheets("PLANNER_ONGOING_DISPLAY_SHEET").Activate
    Range("C4").Select
    ' Set search variable value.
    x = "test 73"
    ' Set Boolean variable "found" to false.
    found = False
    ' Set Do loop to stop at empty cell.
    Do Until IsEmpty(ActiveCell)
        ' Check active cell for search value.
        If ActiveCell.Value = x Then
            found = True
            Exit Do
        End If
        ' Step down 1 row from present location.
        ActiveCell.Offset(1, 0).Select
    Loop
    ' Check for found.
    If found = True Then
        MsgBox "Value found in cell " & ActiveCell.Address
    Else
        MsgBox "Value not found"
    End If
End Sub

Answer 1

您可以采取更简单的方法，同时avoiding .Activate and .Select：

Sub Test3()
  Dim x As String, y As String
  Dim found As Boolean
  Dim i As Integer, lastRow As Long

  lastRow = Worksheets("PLANNER_ONGOING_DISPLAY_SHEET").Cells(Rows.Count, 3).End(xlUp).Row

  x = "test 73"

  For i = 4 To lastRow
    'If you need to compare it to a cell in sheet2 you can also set the value of x here
    y = Worksheets("PLANNER_ONGOING_DISPLAY_SHEET").Cells(i, 3).Value2
    If y = x Then
        ' Do action here, example:
        MsgBox "Value found in cell " & "C" & i
    End If

  Next i

End Sub

这将遍历C 列中所有使用的单元格，并将它们与 x 进行比较。如果单元格匹配，则通过MsgBox 返回其行号。