从 Groovy 中的委托范围获取变量答案

【问题标题】：Get variables from delegate scope in Groovy从 Groovy 中的委托范围获取变量
【发布时间】：2015-09-02 22:59:57
【问题描述】：

我正在尝试编写 Jenkins Job DSL 脚本，并希望尽可能以声明方式/DRY-ly 方式编写它。 Jenkins 任务通过 MultiJob 调用其他一些任务。我的 Groovy 最初看起来像这样（所有内容都包含在一个类中，因为它在其他地方被引用）：

static void buildDownstream(def parentJob, String commit_a="master",
    String commit_b="master") {
  parentJob.with {
    steps {
      phase('Phase') {
        job("name_1") {
          prop('COMMIT_A', commit_a)
          nodeLabel('NODE_LABEL', NODE_LABEL_MAP["name_1"])
          killPhaseCondition('NEVER')
        }
        job("name_2") {
          prop('COMMIT_A', commit_a)
          prop('COMMIT_B', commit_b)
          nodeLabel('NODE_LABEL', NODE_LABEL_MAP["name_2"])
          killPhaseCondition('NEVER')
        }
        job("name_3") {
          prop('COMMIT_A', commit_a)
          prop('COMMIT_B', commit_b)
          nodeLabel('NODE_LABEL', NODE_LABEL_MAP["name_3"])
          killPhaseCondition('NEVER')
        }
      }
    }
  }
}

我想抽象出包含大量重复的工作创造。我最终得到了这样奇怪的东西：

static void buildDownstream(def parentJob, String commit_a="master",
    String commit_b="master") {
  parentJob.with {
    steps {
      phase('Phase') {
        def phase = ({ owner })();
        { ->
          add_node_label=true;
          { ->
            commit_a = null;
            def self = ({ owner })();
            addJob("name_1", self).call(phase);
          }
          def self = ({ owner })();
          addJob("name_2", self).call(phase);
          addJob("name_3", self).call(phase);
        }
      }
    }
  }
}

private static Closure addJob(String job_name, Closure callingClosure) {
  return { phase ->
    def job_config = {
      if(commit_a != null) {
        prop('COMMIT_A', commit_a)
      }
      if(commit_b != null) {
        prop('COMMIT_B', commit_b)
      }
      if(add_node_label == true) {
        nodeLabel('NODE_LABEL', NODE_LABEL_MAP[job_name])
      }
      killPhaseCondition('NEVER')
    }

    job_config.delegate = callingClosure
    job_config.resolveStrategy = Closure.DELEGATE_ONLY
    phase.job(job_name, job_config)
  }
}

这可能完全不是惯用的 Groovy（所有这些 def self = ({ owner })() 的东西都不适合我），根本不起作用。

基本上，我想将callingClosure 范围内的所有变量传递给job_config 闭包，而无需将所有变量作为参数显式传递。（显式传递参数映射是可行的，但是当有很多参数时它会变得笨拙。）我该怎么做？

（P.S：目前，Groovy 正在尝试将 job_config 内的 commit_a 变量解析为来自 javaposse.jobdsl.dsl.helpers.step.PhaseContext，我觉得这很奇怪；我没有明确地将委托设置为 PhaseContext 内的闭包?)

编辑：从another SO question，看来我可以设置phase = delegate（默认为owner？）而不是({ owner })()，并且没问题；我也不是很明白，因为job 是PhaseContext 的属性，而不是它的父级（？）

【问题讨论】：

如果你想访问变量，为什么不把闭包作为参数传递呢？闭包自然也可以访问其所有者变量。我刚刚发布了一个关于代表的问题，也许它可以帮助你：stackoverflow.com/questions/32368483/…
感谢您的建议！我最终做了类似的事情（只是将所有参数作为地图传递）。

标签： groovy jenkins jenkins-job-dsl

【解决方案1】：

好吧，我最终没有尝试让 Groovy 从委托上下文中隐式解析变量，而是在映射中传递参数。

static void buildDownstream(def parentJob, 
    String commit_a="master", String commit_b="master") {
  parentJob.with {
    steps {
      phase('Tests') {
        def params = [COMMIT_A:commit_a] 
        this.getTestJob(delegate, "name_1", params)
        params.COMMIT_B = commit_b
        this.getTestJob(delegate, "name_2", params)
        this.getTestJob(delegate, "name_3", params)
        continuationCondition('ALWAYS')
      }
    }
  }
}

private static void getTestJob(def phase, String job_name, 
    Map properties) {
  phase.job(job_name) {
    properties.each { k, v -> prop(k, v) }
    killPhaseCondition('NEVER')
  }
}

我原来方法的一个问题是我试图访问闭包中的局部变量，但这需要对闭包进行评估；事实证明这很奇怪，我想我不应该尝试这样做。

【讨论】：