在excel中分配日期是“营业时间”还是“营业时间以外”的公式答案

【问题标题】：Formula to Assign whether a date is "In Business Hours" or "Outside Business Hours" in excel在excel中分配日期是“营业时间”还是“营业时间以外”的公式
【发布时间】：2017-09-14 08:58:31
【问题描述】：

我正在尝试创建一个公式，以根据通话日期和时间确定电话是在工作时间之内还是工作时间之外拨打的

营业时间为周一至周五上午 8 点至晚上 8 点和周六上午 8 点至下午 2 点。

所以基本上我需要创建公式的是；

如果电话是星期一、星期二、星期三、星期四、星期五并且时间是 >8 并且 8 和

对于其他所有内容，请显示“非营业时间”

谢谢

【问题讨论】：

您有任何测试解决方案，以便我们消除已经尝试过的解决方案吗？

标签： excel formulas

【解决方案1】：

这个公式应该足够了：

=IF(AND(WEEKDAY(A2)>1,MOD(A2,1)*24>=8,MOD(A2,1)*24<=IF(WEEKDAY(A2)=7,14,20)),"In","Out")

【讨论】：

【解决方案2】：

如果您的日期从单元格A2 开始，请在单元格B2 中输入此公式并将其拖到底部。你的日期应该是这种格式9/16/2017 1:05:00 PM。

=IF(WEEKDAY(A2,2)=7,"Outside of Business hours",IF(WEEKDAY(A2,2)=6,IF(AND(MOD(A2,1)<TIME(14,0,0),MOD(A2,1)>TIME(8,0,0)),"Inside Business Hours","Outside of Business Hours"),IF(AND(MOD(A2,1)<TIME(20,0,0),MOD(A2,1)>TIME(8,0,0)),"Inside Business Hours","Outside of Business Hours")))

【讨论】：

它也应该适用于该类型，只需检查日期是否真的被格式化为日期。（如果您将格式更改为一般格式，它应该给您一个大数字，例如 42992.234423）
谢谢，您能按回答投票吗？干杯。

【解决方案3】：

这些是 D1:G8 范围内的开放时间：

日期和时间在 A2 中：04.09.2017 20:00:00

这是公式： =IF(AND(TIME(HOUR(A2);MINUTE(A2);SECOND(A2)) > VLOOKUP(WEEKDAY(A2);E$2:G$8;2;FALSE)/24;TIME(HOUR(A2);MINUTE(A2);SECOND(A2)) < VLOOKUP(WEEKDAY(A2);E$2:G$8;3;FALSE)/24); "inside"; "outside")

我希望我的英文名字是正确的。这是我的德语原件：

=WENN(UND(ZEIT(STUNDE(A2);MINUTE(A2);SEKUNDE(A2)) > SVERWEIS(WOCHENTAG(A2);E$2:G$8;2;FALSCH)/24;ZEIT(STUNDE(A2);MINUTE(A2);SEKUNDE(A2)) < SVERWEIS(WOCHENTAG(A2);E$2:G$8;3;FALSCH)/24); "inside"; "outside")

【讨论】：

为什么这个例子需要分钟和秒？看起来有点矫枉过正。
例如20:10 不在营业时间。要么将 20:10 裁剪为 20（这也需要一个额外的公式），要么你选择准确的时间。但是，确切时间的优势在于，像 20:05 关闭这样的弯曲时间也是可能的。仅使用全时不提供此功能。

【解决方案4】：

你可以试试下面的公式。

=IF(AND(WEEKDAY(A1)>1,WEEKDAY(A1)<7),IF(AND(A1-INT(A1)>=TIMEVALUE("08:00 AM"),A1-INT(A1)<=TIMEVALUE("08:00 PM")),"Inside Business Hours","Outside Business Hours"),IF(WEEKDAY(A1)=7,IF(AND(A1-INT(A1)>=TIMEVALUE("08:00 AM"),A1-INT(A1)<=TIMEVALUE("02:00 PM")),"Inside Business Hours","Outside Business Hours"),"Outside Business Hours"))

查看图片以供参考。

在上面的公式中，

WEEKDAY(A2) 将给出星期几（默认情况下，它给出 1 表示周日，7 表示周六）
A2-INT(A2) 将从DataTime 单元格中提取Time
TIMEVALUE("08:00 AM") 将在字符串中给出时间的十进制数

【讨论】：