SPSS Syntax - 基于 3 个变量的新变量

Question

我需要基于 3 个变量创建一个新变量。

如果某人针对 3 个变量中的任何 1 个被编码为 1，则他们在新变量中被编码为 1

如果它们不在任何变量上编码 1，而是在 3 个变量中的任何一个上编码为 2，则它们在新变量中被编码为 2

其他的都编码为 99

在语法上，我写成这样：

IF (Keep_Any=1 OR Find_Any=1 OR Improve_Any=1) Keep_Find_Improve=1.
IF ((Keep_Find_Improve~= 1) & (Keep_Any=2 | Find_Any=2 | Improve_Any=2)) Keep_Find_Improve=2.
IF (Keep_Find_Improve~=1 & Keep_Find_Improve~=2) Keep_Find_Improve=99.
EXECUTE.

但是，第一部分正确识别编码为 1 的案例，但其余语法不起作用。尽管使用了一些在其他变量上使用完全相同逻辑的语法，但这是在：

COMPUTE Keep_Any= Q9a_recoded = 1 | Q9b_recoded = 1 | Q9c_recoded = 1.
EXECUTE.

IF (Q9A_recoded=1 OR Q9B_recoded=1 OR Q9C_recoded=1) Keep_Any=1. 
IF ((Keep_Any~=1) & (Q9A_recoded= 2 OR Q9B_recoded=2 OR Q9C_recoded=2)) Keep_Any=2.
IF (Keep_Any~=1 & Keep_Any~=2) Keep_Any=99.
EXECUTE.

有没有人知道为什么会发生这种情况以及如何解决它？

Answer 1

试试：

COMPUTE Target1=99.
COMPUTE Target1=ANY(2, V1, V2, V3).
COMPUTE Target1=ANY(1, V1, V2, V3).

或者更好（更高效，即使代码行更多）

DO IF ANY(1, V1, V2, V3)=1.
   COMPUTE Target2= 1.
ELSE IF ANY(2, V1, V2, V3)=1.
  COMPUTE Target2 = 2.
ELSE.
  COMPUTE Target2=99.
END IF.

Answer 2

您的语法不起作用的原因是您使用的第二个条件：
IF ((Keep_Find_Improve~= 1) & ...
当第一个条件不满足时，Keep_Find_Improve 仍然缺失，因此不满足~=1 的条件。 IF (Keep_Any~=1 & Keep_Any~=2) 也是如此。 所以你不应该将Keep_Find_Improve 与 1 或 2 进行比较，你应该检查它是否收到了一个值或者它是否仍然丢失：

IF (Keep_Any=1 OR Find_Any=1 OR Improve_Any=1) Keep_Find_Improve=1.
IF (missing(Keep_Find_Improve) & (Keep_Any=2 | Find_Any=2 | Improve_Any=2)) Keep_Find_Improve=2.
IF missing(Keep_Find_Improve) Keep_Find_Improve=99.
* alternatively: recode Keep_Find_Improve(miss=99).
EXECUTE.

说了这么多，我建议你使用@JigneshSutar 建议的更高级的代码。