批处理文件不保留变量

Question

为什么CMD.exe终止时下面的批处理文件不保留变量

@echo off
cmd /c "set var=hi"
if defined var (echo var is defined ("var=%var%")) else (echo var isn't defined)
pause
exit

有什么方法可以使用 CMD /c，同时保留变量？为什么 CMD /c 不保留变量？

Answer 1

CMD /C 启动一个新的子进程，该子进程有自己的环境空间，变量存储在内存中。当该进程终止时，相关的环境空间就会丢失，因此您当然会丢失在那里定义的所有变量的定义。

子进程无法直接访问或操作父进程的变量。

如果您正在执行一个简单的命令并且可以控制任何输出，那么您可以将定义写入标准输出并让 FOR /F 捕获输出，以便您可以在父进程中设置值。但是您需要延迟扩展。

注意 - 这个例子很空洞，但它应该能说明问题

for /f "delims=" %%A in ('cmd /v:on /c "set var=hi&echo "var=!var!""') do set %%A

但就识别引用的内容、需要转义的内容而言，事情可能会变得复杂......

如果您创建一个批处理脚本来完成这项工作并使用 FOR /F 执行它，那么可以简化生活。

test.bat

@echo off
set var1=hi
set var2=Ain't this fun
set var3=bye
setlocal enableDelayedExpansion
for %%V in (var1 var2 var3) do echo "%%V=!%%V!"

ma​​in.bat

@echo off
for /f "delims=" %%A in ('cmd /c test.bat') do set %%A

其实 FOR /F 使用的是隐式的 CMD /C，你不再需要在命令中开启延迟扩展，所以你可以抛弃显式的 CMD /C

@echo off
for /f "delims=" %%A in ('test.bat') do set %%A

如果您无法控制输出，则必须将值写入一个临时文件，然后主脚本可以加载该文件。您可能很想编写一个定义变量的临时批处理脚本，但是根据变量的内容，您可能不得不转义某些字符。最安全的选择是使用延迟扩展写出变量名和值，让父进程使用 FOR /F 加载进来。

test2.bat

@echo off
set var1=hi
set var2=Ain't this fun
set var3=bye
echo Here is some output that must be preserved, unrelated to variables
setlocal enableDelayedExpansion
(for %%V in (var1 var2 var3) do echo "%%V=!%%V!") >"%temp%\vars.temp"

ma​​in.bat

@echo off
setlocal disableDelayedExpansion
cmd /c test2.bat
call "%temp%\vars.bat"
for /f "usebackq delims=" %%V in ("%temp%\vars.temp") do set "%%V"
del "%temp%\vars.temp"

注意，在加载变量时，必须在主进程中禁用延迟扩展，否则在扩展%%V时会丢失值中的任何!字符。

但为了稳健，您应该采取措施确保每个实例化使用唯一的临时文件名，以便同时运行不会相互干扰。