多线程 Delphi 停止

Question

我有一个框架，在它里面我有一个线程，这个前面和运行时的创建，每次点击给按钮它都会创建一个新的框架，并且在表单中可能有无数个。问题是......我创建了第一个，创建第​​二个时线程正常启动，第一个线程开始，第二个开始，如果我再次点击，第一个和第二个静止，第三个开始，如果我关闭第三，第二回工作，因为这种情况？ 谢谢

constructor TMy_Thread.Create(fraConnect : TfraConnect);
begin
  inherited Create(True);
  Priority        := tpTimeCritical;
  FreeOnTerminate := true;
  fraConnectT     := fraConnect;
end;

procedure TMy_Thread.Execute;
begin
  Synchronize(Teste);
end;

procedure TMy_Thread.TEste;
var
  iSize : Int64;
  iCnt  : Integer;
  Msg : TMsg ;
begin
  inherited;
  with fraConnectT do begin
    While not Terminated do begin
      Log(fraConnectT.Name,'');
      Application.ProcessMessages;
    end;
  end;
end;


////////////////

procedure TfraConnect.Click(Sender: TObject);
var
  Sc : TMy_Thread;
begin
  Sc                    := TMy_Thread.Create(Self);
  try
    iTela            := 0;
    Sc.Execute;
  finally
    Sc.Terminate;
  end;
end;

Answer 1

您没有正确使用TThread。您没有启动线程（因此终止时它不会自行释放），您正在直接调用Execute()，您正在Synchronizeing 整个Execute()。所以Execute()在主线程中运行，调用ProcessMessages()来允许新的按钮点击，它调用Execute()阻塞之前的Execute()直到新的Execute()退出，等等。这就是您出现所见症状的原因。

要解决此问题，您需要执行以下操作：

• 在线程构造函数中，改为调用inherited Create(False)。这允许线程自动开始运行。否则，必须在构造函数退出后调用线程的Resume()或Start()方法。

• 从Click() 中删除Execute()。让正在运行的线程调用Execute()。

• 从Teste() 中删除ProcessMessages()。永远不需要在线程中调用ProcessMessages()（除非在主线程中运行的Synchronized 或Queued 代码内部调用它，但即便如此也应尽可能避免）。

• 只有 Synchronize() 实际上需要在主线程中运行的小代码块 - 在辅助线程中不起作用的代码、需要访问 UI 的代码、需要访问多个线程共享的资源等。你的大部分线程代码不应该是Synchronized，这首先违背了使用线程的目的。

试试这样的：

type
  fraConnect = class;
  TMy_Thread = class(TThread)
  private
    fraConnectT : TfraConnect;
    procedure DoLog;
  protected
    procedure Execute; override;
  public
    constructor Create(fraConnect : TfraConnect);
    property Terminated;
  end;

...

constructor TMy_Thread.Create(fraConnect : TfraConnect);
begin
  inherited Create(True);
  Priority        := tpTimeCritical;
  FreeOnTerminate := true;
  fraConnectT     := fraConnect;
end;

procedure TMy_Thread.Execute;
begin
  with fraConnectT do begin
    While not Terminated do begin
      // assuming Log() is not thread-safe...
      Synchronize(DoLog);
      Sleep(100);
    end;
  end;
end;

procedure TMy_Thread.DoLog;
begin
  Log(fraConnectT.Name,'');
end;

type
  TMy_Thread = class;
  TfraConnect = class(TFrame)
    Start: TButton;
    Stop: TButton;
    StartClick(Sender: TObject);
    StopClick(Sender: TObject);
  private
    Sc: TMy_Thread;
    procedure ThreadTerminated(Sender: TObject);
  end;

...

procedure TfraConnect.StartClick(Sender: TObject);
begin
  if (not Assigned(Sc)) or Sc.Terminated then
  begin
    Sc := TMy_Thread.Create(Self);
    Sc.OnTerminate := ThreadTerminated;
    Sc.Resume; // or Sc.Start;
  end;
end;

procedure TfraConnect.StopClick(Sender: TObject);
begin
  if Assigned(Sc) then
    Sc.Terminate;
end;

procedure TfraConnect.ThreadTerminated(Sender: TObject);
begin
  if Sc = Sender then
    Sc := nil;
end;