全局符号“%self”需要 Perl 模块中的显式包名

Question

我正在编写一个 Perl 模块，并且在运行测试时遇到了这个令人困惑的错误消息。

sub new {
  my $class = shift;
  my $self = @_;
  $word = $self{word} || die "No word provided.";
  @definitions = @{decode_json(get($urban_url . $word))->{'list'}} || die "Error during fetch/decode.";
  @tags = @{decode_json(get($urban_url . $word))->{'tags'}} || "Error during fetch/decode.";
  bless($self, $class);
  return $self;
}

如您所见，$self 已正确声明。 word 是在new 子例程之上声明的全局变量。在use语句的每个测试中都会发生失败，并追溯到$word的分配。

Answer 1

标量 $self 已声明，但您使用的是不存在的哈希 %self。

my $self = @_;
... $self{word} ...

应该是

my %args = @_;
... $args{word} ...

---

当然，你仍然需要$self。您希望它是对新空哈希的引用。你需要：

my $self = {};     # Creates an anon hash and places a reference to it in $self.

---

接下来，以下不做你想要的。

my @foos = @{ REF } || die(LIST);

以下将：

my @foos = @{ REF } or die(LIST);

以下内容可能会更有用：

my $foos = REF or die(LIST);

---

最后，您永远不会将数据实际存储在对象中。

my $data = decode_json(get($urban_url . $word));
   or die("Error during fetch/decode\n");

$self->{definitions} = $data->{list};
$self->{tags}        = $data->{tags};

---

经过一些样式更改后，您会得到我会使用的东西。

sub new {
   my ($class, %args) = @_;

   my $word = $args{word}
      or die("No word provided");

   my $data = decode_json(get($urban_url . $word));
      or die("Error during fetch/decode\n");

   my $self = bless({}, $class);

   $self->{definitions} = $data->{list};
   $self->{tags}        = $data->{tags};

   return $self;
}

我撒谎了。我怀疑我会在对象构造函数中执行 Web 请求并解析响应。