如何按文件名和数字排序文件列表？

Question

我在一个目录中有一堆文件，我试图根据它们的类型来获取它们。一旦我有了它们，我想按文件名排序（其中有一个数字，我想这样排序）

我返回的文件是：

file-1.txt
file-2.txt
...
file-10.txt
file-11.txt
...
file-20.txt

但是我得到它们的顺序看起来更接近于这个：

file-1.txt
file-10.txt
file-11.txt
...
file-2.txt
file-20.txt

现在我正在使用Directory.GetFiles() 并尝试使用linq OrderBy 属性。但是，我在订购文件列表（如上面的第一个列表）时需要做的事情非常糟糕。

Directory.GetFiles() 似乎正在返回字符串列表，因此我无法获取文件属性列表，例如 filename 或 name。

这是我目前的代码：

documentPages = Directory.GetFiles(documentPath, "*.txt").OrderBy(Function(p) p).ToList()

有人有什么想法吗？

Answer 1

听起来您可能正在寻找“NaturalSort” - 文件资源管理器用于对包含数字的文件名进行排序的那种显示。为此，您需要一个自定义比较器：

Imports System.Runtime.InteropServices

Partial Class NativeMethods
    <DllImport("shlwapi.dll", CharSet:=CharSet.Unicode)>
    Private Shared Function StrCmpLogicalW(s1 As String, s2 As String) As Int32
    End Function

    Friend Shared Function NaturalStringCompare(str1 As String, str2 As String) As Int32
        Return StrCmpLogicalW(str1, str2)
    End Function
End Class

Public Class NaturalStringComparer
    Implements IComparer(Of String)

    Public Function Compare(x As String, y As String) As Integer Implements IComparer(Of String).Compare
        Return NativeMethods.NaturalStringCompare(x, y)
    End Function
End Class

用它对你得到的结果进行排序：

Dim myComparer As New NaturalStringComparer

' OP post only shows the filename without path, so strip off path:
' (wont affect the result, just the display)
Dim files = Directory.EnumerateFiles(path_name_here).
                 Select(Function(s) Path.GetFileName(s)).ToList
Console.WriteLine("Before: {0}", String.Join(", ", files))

' sort the list using the Natural Comparer:
files.Sort(myComparer)
Console.WriteLine("After: {0}", String.Join(", ", files))

结果（单行以节省空间）：

之前：file-1.txt、file-10.txt、file-11.txt、file-19.txt、file-2.txt、file-20.txt、file-3.txt、file-9 .txt、文件-99.txt
之后：file-1.txt、file-2.txt、file-3.txt、file-9.txt、file-10.txt、file-11.txt、file-19.txt、file-20.txt、文件-99.txt

这样做的一个优点是它不依赖于特定的模式或编码。它更通用，可以处理文本中的多组数字：

权力的游戏\4 - 群鸦盛宴\1 - Prologue.mp3
权力的游戏\4 - 群鸦盛宴\2 - 先知.mp3
...
权力的游戏\4 - 乌鸦的盛宴\10 - 布蕾妮 II.mp3
权力的游戏\4 - 群鸦的盛宴\11 - Sansa.mp3

---

Natural String Sort 非常方便，我个人不介意通过创建扩展来污染 Intellisense：

' List<string> version
<Extension>
Function ToNaturalSort(l As List(Of String)) As List(Of String)
    l.Sort(New NaturalStringComparer())
    Return l
End Function

' array version
<Extension>
Function ToNaturalSort(a As String()) As String()
    Array.Sort(a, New NaturalStringComparer())
    Return a
End Function

现在使用更简单：

Dim files = Directory.EnumerateFiles(your_path).
              Select(Function(s) Path.GetFileName(s)).
              ToList.
              ToNaturalSort()

' or without the path stripping:
Dim files = Directory.EnumerateFiles(your_path).ToList.ToNaturalSort()

Answer 2

我假设 file 和 .txt 部分是可变的，在这里只是作为文件名和类型的占位符可以变化。

我不经常使用正则表达式，所以这可能还需要一些工作，但这绝对是你需要去的方向：

Dim exp As String = "-([0-9]+)[.][^.]*$"
documentPages = Directory.GetFiles(documentPath, "*.txt").OrderBy(Function(p) Integer.Parse(Regex.Matches(p, exp)(0).Groups(1).Value)).ToList()

---

再看一遍，我发现我错过了您正在按*.txt 文件过滤，这可以帮助我们缩小表达式：

Dim exp As String = "-([0-9]+)[.]txt$"

包含测试数据的其他答案带来的另一个可能的改进是允许- 和数字之间的空格：

Dim exp As String = "-[ ]*([0-9]+)[.]txt$"

---

进一步值得注意的是，如果存在不符合模式的文本文件，上述将失败。如果需要，我们可以考虑到这一点：

Dim exp As String = "-[ ]*([0-9]+)[.][^.]*$"
Dim docs = Directory.GetFiles(documentPath, "*.txt")
documentPages = docs.OrderBy(
     Function(p) 
            Dim matches As MatchCollection = Regex.Matches(p, exp)
            If matches.Count = 0 OrElse matches(0).Groups.Count < 2 Then Return 0
            Return Integer.Parse(matches(0).Groups(1).Value)
     End Function).ToList()

您也可以使用Integer.MaxValue 作为默认选项，具体取决于您希望它们出现在列表的开头还是结尾。