如何使用 XSLT 在 XML 文件中复制子元素 n 次

Question

我对 XSLT 很陌生。我需要转换和复制子节点 1000 次，并增加 id 节点，以便它们每次都不同。

输入 XML：

<?xml version="1.0" encoding="ISO-8859-1"?>
<?xml-stylesheet type="text/xsl" href="test.xsl"?>
<catalog>
    <cd>
        <id>2017</id>
        <artist>Bob Dylan</artist>
        <country>USA</country>
        <company>Columbia</company>
        <price>10.90</price>
        <year>1985</year>
    </cd>
</catalog>

我的 XSLT：但它只复制一次

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet version="1.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

我需要的是：请帮忙

<?xml version="1.0" encoding="UTF-8"?><?xml-stylesheet type="text/xsl"   href="test.xsl"?>
<catalog>
    <cd>
        <id>2017</id>
        <artist>Bob Dylan</artist>
        <country>USA</country>
        <company>Columbia</company>
        <price>10.90</price>
        <year>1985</year>
   </cd>
    <cd>
        <id>2018</id>
        <artist>Bob Dylan</artist>
        <country>USA</country>
        <company>Columbia</company>
        <price>10.90</price>
        <year>1985</year>
   </cd>
   <cd>
        <id>2019</id>
        <artist>Bob Dylan</artist>
        <country>USA</country>
        <company>Columbia</company>
        <price>10.90</price>
        <year>1985</year>
   </cd>

    <!-- 997 more times with ID increment +1 each time  -->

</catalog>

Answer 1

在 XSLT 1.0 中，您可以通过使用递归模板来实现这一点。所以模板反复调用自己，每次递增一个参数，直到达到要求的限制。

试试这个 XSLT（根据需要将参数 5 替换为 1000）

<xsl:stylesheet version="1.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:param name="total" select="5" />

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="cd" name="cd">
    <xsl:param name="count" select="1" />
    <xsl:copy>
        <xsl:apply-templates select="@*|node()">
            <xsl:with-param name="count" select="$count" />
        </xsl:apply-templates>
    </xsl:copy>
    <xsl:if test="$count &lt; $total">
        <xsl:apply-templates select=".">
            <xsl:with-param name="count" select="$count + 1" />
        </xsl:apply-templates>
    </xsl:if>
</xsl:template>

<xsl:template match="id">
    <xsl:param name="count" />
    <xsl:copy>
        <xsl:value-of select="number() + $count - 1" />
    </xsl:copy>
</xsl:template>
</xsl:stylesheet>

编辑：如果您想要相同的逻辑但对于cd 下的其他元素，只需修改匹配id 的模板以将它们包含在匹配中。比如……

<xsl:template match="id|year">
    <xsl:param name="count" />
    <xsl:copy>
        <xsl:value-of select="number() + $count - 1" />
    </xsl:copy>
</xsl:template>

在http://xsltransform.net/gWEamLv查看此操作