Delphi 检查默认打印机失败

Question

当有人尝试打印但没有设置默认打印机时，我使用下面的代码来防止出现异常。我收到了一个用户的报告，该用户使用 citrix 远程使用该软件，该用户将网络打印机作为默认打印机。它在调用 GetPrinter 时引发异常，并显示消息“当前未选择默认打印机”。他们从其他应用程序打印没有问题。这里出了什么问题？

function CheckForDefaultPrinter: boolean;
var
  FDevice:     PChar;
  FDriver:     PChar;
  FPort:       PChar;
  FHandle:     THandle;
  CurrentPrinterName: string;
begin
  //ensure default printer selected - bypass printer.pas bug
  Printer.PrinterIndex := Printer.PrinterIndex;
  GetMem (FDevice, 255);
  GetMem (FDriver, 255);
  GetMem (FPort, 255);
  try
    try
      Printers.Printer.GetPrinter(FDevice, FDriver, FPort, FHandle);
    except
      on E:Exception do
        ShowMessage(E.Message);
    end;
    CurrentPrinterName := FDevice;
  finally
    if FDevice <> nil then FreeMem (FDevice, 255);
    if FDriver <> nil then FreeMem (FDriver, 255);
    if FPort <> nil then FreeMem (FPort, 255);
  end;

  if CurrentPrinterName = '' then
  begin
    MessageDlg('You do not have a default printer defined.' +
               #13#13 + 'Please select a printer before running a report.'+
               #13#13 + 'Or the default printer name is blank. Please assign the printer a name.',
               mtError,[mbOK],0);
    Result:= False;
  end
  else
    Result:= True;
end;

Answer 1

在您发布的代码可以检查之前发生错误，因为它在第一次访问Printer时失败。

在尝试使用全局 Printer 之前，您应该直接使用 WinAPI GetDefaultPrinter 函数来查看是否存在默认打印机。这是一个示例控制台应用程序（它使用了比最新版本的 Delphi 中包含的更简单的函数声明）来演示如何这样做。该示例在 XE 10 Seattle 中编译并在 Windows 7 64 位上进行了测试。

program Project1;

{$APPTYPE CONSOLE}

uses
  System.SysUtils, WinAPI.Windows;

function GetDefaultPrinter(Buffer: PChar; var BufferSize: DWord): BOOL; stdcall;
  external 'winspool.drv' name 'GetDefaultPrinterW'; // GetDefaultPrinterA on pre-Unicode Delphi versions

var
  Buff: string;
  BuffSize, Err: DWord;
begin
  // Get size of buffer needed. 
  GetDefaultPrinter(nil, BuffSize);
  SetLength(Buff, BuffSize);
  // If this call fails, and GetLastError returns
  // ERROR_FILE_NOT_FOUND, there is no default printer assigned.
  if GetDefaultPrinter(PChar(Buff), BuffSize) then
    WriteLn('Default printer: ', Buff)
  else
  begin
    Err := GetLastError();
    if Err = ERROR_FILE_NOT_FOUND then
      WriteLn('No default printer assigned')
    else
      WriteLn('Failed. Error: ', Err);
  end;
  ReadLn;
end.

请注意，根据文档，返回值包括终止 NULL (#0)。要删除它，只需在调用 GetDefaultPrinter 返回后使用 SetLength(Buff, Length(Buff) - 1)。

Answer 2

在 Windows 上，您可以假设如果有超过 0（零）台打印机，则存在默认打印机。 除非您的应用程序作为服务运行，否则此假设是安全的。

所以你只需要这个：

if (Printer.Printers.Count=0) then ShowMessage('Please install a printer before attempting to print.');

您需要在访问打印机对象上的大多数其他属性/方法之前进行此检查。

如果您的应用程序作为服务运行，则不会有默认打印机。在您在代码中分配值之前，此处的 PrinterIndex 将为 -1。

Answer 3

我使用 Delphi XE6、Win7Pro 测试了您的代码。只是换了一行

GetMem (FPort, 255);
 try
  try
    Printer.GetPrinter(FDevice, FDriver, FPort, FHandle); // HERE

except
  on E:Exception do
    ShowMessage(E.Message);
end;

它默认使用联网打印机，即使在拔下电缆的情况下也是如此。