Emacs 最快的 C++ 编译过程？

Question

以下是用例：我在技术博客上阅读了一篇关于 C++ 的文章 （多重继承失败和多线程失败等：）。 通常它们带有一些代码。它几乎总是一个文件，我几乎总是 想运行它并玩弄它。

我想用 Emacs 做这件事，我想快速做， 与最少（或相当少）的击键一样。

所以假设我已经在它自己的文件夹中创建了一个multiple_inheritance.cc 文件 并粘贴代码。如何快速获得可执行文件？

这就是我现在正在做的事情（希望有人会改进它。）

(defun cpp-generate-makefile ()
  (interactive)
  (let* ((n-buffer (buffer-file-name))
         (n-file (file-name-nondirectory n-buffer))
         (n-target (file-name-sans-extension n-file))
         (n-makefile (concat (file-name-directory n-buffer) "Makefile")))
    (if (file-exists-p n-makefile)
        (when (called-interactively-p 'any)
          (message "Makefile already exists"))
      (with-current-buffer (find-file-noselect n-makefile)
        (insert 
         (concat n-target ": " n-file 
                 "\n\tg++ -g -O2 -std=c++0x -o $@ $^\n\n"
                 "clean: \n\trm -f " n-target "\n"))
        (save-buffer)))))

(defun cpp-run ()
  (interactive)
  (save-buffer)
  (cpp-generate-makefile)
  (compile "make"))

(add-hook 'c++-mode-hook
      (lambda()
            ;; ...
            (define-key c++-mode-map [f5] 'cpp-run)))

以下是目前让我慢下来的几件事：

1. compile 询问我是否要保存任何与 C++ 完全无关的打开文件。
2. 我想在*compilation* 缓冲区中有一个点，以防出现错误。 我查看了compile.el，其中定义了compilation-num-errors-found， 但该变量并未在该文件的任何地方使用。
3. 另一方面，如果没有错误（我只需要一个谓词）， 为什么不启动term 并运行程序？

Answer 1

总结一下cmets中的答案。

1. 更改compilation-ask-about-save 的值。如果您不想全局更改它（使用 setq），您可以通过将其包装在 (let ((compilation-ask-about-save nil)) ...function contents...) 语句中来在函数内部更改它。
2. 快速绑定下一个错误：(define-key c++-mode-map "\M-j" 'next-error)。我个人为此使用 global-set-key，只是因为它在很多模式中都很有用。
3. 将函数中的编译命令替换为(compile "make && ./a.out")（当然使用可执行文件的名称）。

希望这会有所帮助。

Answer 2

我更新了代码，我必须将run 目标添加到Makefile。 我还为 C 添加了一个扩展：

(defvar cpp-generate-compiler "g++ -g -O2 -std=c++0x")

(defun cpp-generate-makefile ()
  (interactive)
  (let* ((n-buffer (buffer-file-name))
         (n-file (file-name-nondirectory n-buffer))
         (n-target (file-name-sans-extension n-file))
         (n-makefile (concat
                       (file-name-directory n-buffer)
                       "Makefile")))
    (if (file-exists-p n-makefile)
        (when (called-interactively-p 'any)
          (message "Makefile already exists"))
      (with-current-buffer (find-file-noselect n-makefile)
        (insert
         (concat n-target ": " n-file
                 (format "\n\t%s -o $@ $^"
                   cpp-generate-compiler)
                 "\n\nclean: \n\trm -f " n-target
                 "\n\nrun: " n-target "\n\t ./" n-target
                 "\n\n.PHONY: clean run\n"))
        (save-buffer)))))

(defun cpp-run ()
  (interactive)
  (save-buffer)
  (cpp-generate-makefile)
  (compile "make run"))

(defun c-run ()
  (interactive)
  (let ((cpp-generate-compiler "gcc -g -O2 -std=c99"))
    (cpp-run)))

(add-hook 'c++-mode-hook
      (lambda()
            ;; ...
            (define-key c++-mode-map [f5] 'cpp-run)))
(add-hook 'c-mode-hook
      (lambda()
            ;; ...
            (define-key c-mode-map [f5] 'c-run)))
            
(setq compilation-ask-about-save nil)
(setq compilation-finish-functions
      (list (lambda(buffer str)
              (unless (string= str "finished\n")
                (push-mark)
                (next-error)))))

有了(setq compilation-ask-about-save nil)，就没有更多了 关于保存的警告（cpp-run 自动保存）。

我只需要记住 M-g n 和 M-g p 导航错误。

现在我的过程几乎是最佳的：从源到结果的一键，以防万一 没有错误。

如果有错误，它是一个额外的M-g n。 现在，如果compile 有办法调用(push-mark)(next-error)...

更新：

感谢@juanleon 的建议，解决了这个问题：

(setq compilation-finish-functions
      (list (lambda(buffer str)
              (unless (string= str "finished\n")
                (push-mark)
                (next-error)))))

但由于某种原因，push-mark 在这种情况下无法正常工作。