从文件读入 Emacs lisp 列表

Question

我有以下文件data.txt

A
B
C
D

我想把这个文件的内容读入一个 Lisp list，比如

(defun read-list-from-file (fn)
  (interactive)
  (list "A" "B" "C" "D"))

(defun my-read ()
  (interactive)
  (let (( mylist (read-list-from-file "data.txt")))
    (print mylist t)))

如何修改read-list-from-file 使其返回相同的列表，而是从作为输入参数fn 给出的文件中读取。文件中的每一行都应该是列表中的一个单独的项目..

Answer 1

这段代码：

(with-current-buffer
    (find-file-noselect "~/data.txt")
  (split-string
   (save-restriction
     (widen)
     (buffer-substring-no-properties
      (point-min)
      (point-max)))
   "\n" t))

更新：

这是一个带有insert-file-contents的版本：

(defun slurp (f)
  (with-temp-buffer
    (insert-file-contents f)
    (buffer-substring-no-properties
       (point-min)
       (point-max))))

(split-string
 (slurp "~/data.txt") "\n" t)

Answer 2

比创建临时缓冲区更容易的是使用f 文件操作库的f-read 函数返回文件的文本内容（默认编码为UTF-8）。 f 是您需要从 MELPA 安装的第三方，请阅读 Xah Lee's 教程了解如何使用 Emacs 包管理系统。然后您可以使用split-string 或s 字符串操作库的s-split（这是对前一个函数的简单包装）：

(s-split "\n" (f-read "~/data.txt") t) ; ("A" "B" "C" "D")

注意： s-split 的第三个参数设置为 t 省略空字符串。您可以使用s-lines，但由于*nix 系统上的文本文件通常包含尾随换行符，因此返回的列表将是("A" "B" "C" "D" "")。您可以使用 dash 列表操作库的 butlast 函数删除最后一个元素，但这在 O(n) 中有效，因此可能坚持使用 s-split，除非您希望在列表中保留空行。