Emacs 中的缓冲区本地覆盖次要模式键绑定答案

【问题标题】：Buffer-locally overriding minor-mode key bindings in EmacsEmacs 中的缓冲区本地覆盖次要模式键绑定
【发布时间】：2012-10-27 17:35:26
【问题描述】：

我想使用一个次要模式来重新绑定一个我绝对想要保留的主要模式键。如何重新绑定密钥而不从全局的次要模式映射中删除它？我知道我可以为此使用define-key，但我想保留其他缓冲区/主要模式的绑定。

谁能帮忙？

【问题讨论】：

标签： emacs

【解决方案1】：

做起来有点麻烦。您可以执行以下操作：

(add-hook '<major-mode>-hook
  (lambda ()
    (let ((oldmap (cdr (assoc '<minor-mode> minor-mode-map-alist)))
          (newmap (make-sparse-keymap)))
      (set-keymap-parent newmap oldmap)
      (define-key newmap [<thekeyIwanttohide>] nil)
      (make-local-variable 'minor-mode-overriding-map-alist)
      (push `(<minor-mode> . ,newmap) minor-mode-overriding-map-alist))))

【讨论】：

太棒了！我很惊讶这个看似简单的任务竟然如此繁琐……
sebhofer：模式特定键映射的全部意图是它们确实在该模式处于活动状态的任何地方生效，所以我不会调用规避该行为的任务完全“看似简单”。鉴于这些情况，这个解决方案看起来相当优雅。
@phils 从有点幼稚的角度来看，任务是：覆盖给定缓冲区中的键绑定。对我来说似乎很简单。

【解决方案2】：

这是一个处理所有繁琐位的函数。

(defun local-set-minor-mode-key (mode key def)
  "Overrides a minor mode keybinding for the local
   buffer, by creating or altering keymaps stored in buffer-local
   `minor-mode-overriding-map-alist'."
  (let* ((oldmap (cdr (assoc mode minor-mode-map-alist)))
         (newmap (or (cdr (assoc mode minor-mode-overriding-map-alist))
                     (let ((map (make-sparse-keymap)))
                       (set-keymap-parent map oldmap)
                       (push `(,mode . ,map) minor-mode-overriding-map-alist) 
                       map))))
    (define-key newmap key def)))

以后就可以了

(local-set-minor-mode-key '<minor-mode> (kbd "key-to-hide") nil)

【讨论】：

【解决方案3】：

在我的例子中，当显示公司完成菜单时，company-mode 覆盖了M-p 和M-n 的cider-repl-mode 绑定。完成菜单的键盘映射是company-active-map，但没有与之对应的次要模式（company-mode 用于菜单不活动时），所以我不能使用任何现有的答案。

这就是我想出的：

(add-hook 'cider-repl-mode-hook
          (lambda ()
            (make-local-variable 'company-active-map)
            (setq company-active-map (copy-tree company-active-map))
            (define-key company-active-map (kbd "M-p") nil)
            (define-key company-active-map (kbd "M-n") nil)))

【讨论】：