xml记事本命令行开关

Question

我想在 XML Notepad 2007 中打开一个 XML 文件，并使用来自批处理文件或 VB6 函数的命令行以不同的名称保存它。此操作的目的是让每个 XML 元素在自己的行上，这是我进一步数据处理所需要的。 我已经找到了如何在 XML Notepad 2007 中打开文件，但找不到任何有关将执行文件“另存为”的开关/参数的信息。

Answer 1

您可以在 VB6 中使用 MSXML 自己完成此操作。这是一个小演示：

Option Explicit

Private Sub ManageUI()
    'Make UI changes based on the relationships of controls and their
    'current values.
    chkStandalone.Enabled = chkOmitXMLDeclaration.Value <> vbChecked
End Sub

Private Sub chkOmitXMLDeclaration_Click()
    ManageUI
End Sub

Private Sub cmdReformat_Click()
    Dim rdrCompact As MSXML2.SAXXMLReader
    Dim wrtFormatted As MSXML2.MXXMLWriter

    Set wrtFormatted = New MSXML2.MXXMLWriter
    With wrtFormatted
        .omitXMLDeclaration = chkOmitXMLDeclaration.Value = vbChecked
        .standalone = chkStandalone.Value = vbChecked
        .indent = chkIndent.Value = vbChecked
        .output = "" 'Tells MXXMLWriter we want Unicode String output.
        Set rdrCompact = New MSXML2.SAXXMLReader
        With rdrCompact
            Set .contentHandler = wrtFormatted
            Set .dtdHandler = wrtFormatted
            Set .errorHandler = wrtFormatted
            .putProperty "http://xml.org/sax/properties/lexical-handler", _
                         wrtFormatted
            .putProperty "http://xml.org/sax/properties/declaration-handler", _
                         wrtFormatted
            .parse txtOriginal.Text
        End With
        txtPrettied.Text = .output
    End With
End Sub

Private Sub Form_Load()
    ManageUI
End Sub