缩进长行标准输出

Question

假设我有一个标准的 80 列终端，执行带有长行输出的命令（即来自ls 的标准输出），该命令分为两行或多行，并且想要缩进我所有 bash 标准输出的续行。

缩进应该是可配置的，1 或 2 或 3 或任何空格。

从这里

lrwxrwxrwx 1 root root 24 Feb 19 1970 sdcard -> /storage/emula
ted/legacy/

到这里

lrwxrwxrwx 1 root root 24 Feb 19 1970 sdcard -> /storage/emula
ted/legacy/

阅读此Indenting multi-line output in a shell script，因此我尝试通过管道传递| sed 's/^/ /'，但给了我完全相反的结果，缩进第一行而不是续行。

理想情况下，每次打开交互式 shell 并执行任何命令时，我都会将脚本放在 profile.rc 中或其他任何地方，长输出会缩进。

Answer 1

我会为此使用awk。

awk -v width="$COLUMNS" -v spaces=4 '
BEGIN {
  pad = sprintf("%*s", spaces, "") # generate `spaces` spaces
}
NF {                               # if current line is not empty
  while (length > width) {         # while length of current line is greater than `width`
    print substr($0, 1, width)     # print `width` chars from the beginning of it
    $0 = pad substr($0, width + 1) # and leave `pad` + remaining chars
  }
  if ($0 != "")                    # if there are remaining chars
    print                          # print them too 
  next
} 1' file

一行：

awk -v w="$COLUMNS" -v s=4 'BEGIN{p=sprintf("%*s",s,"")} NF{while(length>w){print substr($0,1,w);$0=p substr($0,w+1)} if($0!="") print;next} 1'

正如@Mark 在 cmets 中建议的那样，您可以将其放在一个函数中并将其添加到 .bashrc 以方便使用。

function wrap() {
  awk -v w="$COLUMNS" -v s=4 'BEGIN{p=sprintf("%*s",s,"")} NF{while(length>w){print substr($0,1,w);$0=p substr($0,w+1)} if($0!="") print;next} 1'
}

用法：

ls -l | wrap

---

由 Ed Morton 根据请求编辑：

与上面的 oguzismails 脚本非常相似，但应该适用于 Busybox 或任何其他 awk：

$ cat tst.awk
BEGIN { pad = sprintf("%" spaces "s","") }
{
    while ( length($0) > width ) {
        printf "%s", substr($0,1,width)
        $0 = substr($0,width+1)
        if ( $0 != "" ) {
            print ""
            $0 = pad $0
        }
    }
    print
}
$
$ echo '123456789012345678901234567890' | awk -v spaces=3 -v width=30 -f tst.awk
123456789012345678901234567890
$ echo '123456789012345678901234567890' | awk -v spaces=3 -v width=15 -f tst.awk
123456789012345
   678901234567
   890
$ echo '' | awk -v spaces=3 -v width=15 -f tst.awk

$

第一个测试用例表明您没有在全角输入行之后打印空白行，第三个测试用例表明它不会删除空白行。通常我会使用sprintf("%*s",spaces,"") 来创建pad 字符串，但我在评论中看到这在您使用的明显非POSIX awk 中不起作用。

Answer 2

这可能对你有用（GNU sed）：

sed 's/./&\n  /80;P;D' file

这会将行拆分为长度为 80 的行，并将以下行缩进 2 个空格。

或者，如果您愿意：

s='  ' c=80
sed "s/./&\n$s/$c;P;D" file

要防止打印空行，请使用：

sed 's/./&\n/80;s/\n$//;s/\n    /;P;D' file

或更容易：

sed 's/./\n    &/81;P;D' file

Answer 3

使用纯 bash 字符串操作的一种可能解决方案。 您可以使脚本读取stdin 并格式化它读取的任何内容。

MAX_LEN=5  # length of the first/longest line
IND_LEN=2  # number of indentation spaces
short_len="$((MAX_LEN-IND_LEN))"
while read line; do
    printf "${line:0:$MAX_LEN}\n"
    for i in $(seq $MAX_LEN $short_len ${#line}); do
        printf "%*s${line:$i:$short_len}\n" $IND_LEN
    done
done

用法：（假设脚本保存为indent.sh）

$ echo '0123456789' | ./indent.sh
01234
  567
  89