Mathematica 中条件查询的映射选择

Question

使用以下列表，

list = {{a, b, c, d}, {1, 2, 3, 4}, {5, 6, 7, 8}};

是否可以选择第二个值大于 3 的列表。所需的输出如下

{5, 6, 7, 8}

调整以下当前提取列表中所有值>2的代码

Select[#, # > 2 &] & /@ list[[2 ;;]

查询的复杂解决方案可以在这里找到Conditional Data Manipulation in Mathematica

Answer 1

或者，使用Select

Select[list, #[[2]] > 3 &]

输出

{{5, 6, 7, 8}}

Answer 2

在这种情况下Select 是最简单的方法，但Pick 也可以用于相关问题。

list = {{a, b, c, d}, {1, 2, 3, 4}, {5, 6, 7, 8}};

Pick[list, #>3& /@ list[[All, 2]] ]

解释一下，Pick 接受两个相同形状的列表（或嵌套列表），并返回第一个中的每个元素，第二个的对应元素是 True。 （它也可以接受第三个参数来匹配True以外的元素。）

这里，用list[[All, 2]] 提取第二列，然后将测试#>3& 映射到每个元素。然后将其用作选择列表。

---

响应 cmets 500 请求泛化Select 方法：

selectByColumn[array_, index_, value_, range_] :=
  Select[array, #[[index]] > value &][[All, range]]

这允许人们指定：

• array : 要从中提取的输入数组
• index : 用于比较的列索引
• value ：要比较的值
• range ：要从每个结果行中提取的 Part 规范

Answer 3

不同方案的速度比较

有趣的是，Select 总是使用解压数组更快地工作，而对于大型数组，差异大约是一个数量级！点击下表放大：

计时测试代码：

solutions = Hold[
   Select[list, #[[2]] > 3 &],
   Cases[list, _List?(#[[2]] > 3 &)],
   Cases[list, x_List /; x[[2]] > 3],
   Cases[list, {_, x_, ___} /; x > 3],
   Cases[list, {_, _?(# > 3 &), ___}],
   Cases[list, {x___} /; List[x][[2]] > 3],
   Pick[list, UnitStep[list[[All, 2]] - 3], 1],
   Pick[list, # > 3 & /@ list[[All, 2]]]
   ];
testCases = Hold[
   {"Packed Reals", RandomReal[{0, 5}, {dim, dim}]},
   {"Unpacked Reals", 
    Developer`FromPackedArray@RandomReal[{0, 5}, {dim, dim}]},
   {"Packed Integers", RandomInteger[{0, 5}, {dim, dim}]},
   {"Unpacked Integers", 
    Developer`FromPackedArray@RandomInteger[{0, 5}, {dim, dim}]},
   {"Rationals", 
    Rationalize[#, .001] & /@ RandomReal[{0, 5}, {dim, dim}]}
   ];
timing := 
  Function[Null, 
   If[(time = First[Timing[Do[#;, {n}]]]) < .3, 
     Print["Too small timing for ", n, " iterations (dim=", dim, 
      ") of ", HoldForm[#], ": ", time, " seconds!"]; time, time]/n, 
   HoldFirst];
generateTable := 
 Labeled[TableForm[
   Transpose@
    Table[list = testCases[[i, 2]]; 
     tmgs = List @@ (timing /@ solutions); 
     d = Last@MantissaExponent[Min[tmgs]] - 3; 
     Row[{Round[10^-d*#], ".\[Times]", Superscript[10, d]}] & /@ 
      tmgs, {i, 1, Length[testCases]}], 
   TableHeadings -> {List @@ (HoldForm /@ solutions), 
     List @@ testCases[[All, 1]]}, TableAlignments -> Right], 
  Row[{"Average timings for ", dim, "\[Times]", dim, " list"}], Top]

Column[{dim = 5; n = 30000; generateTable, dim = 100; n = 3000; 
  generateTable, dim = 1000; n = 150; generateTable}, Left, 1, 
 Frame -> All, FrameStyle -> Gray]

Answer 4

另一种 Cases 语法。第一项被跳过，第二项被测试为> 3，我们不关心列表的其余部分：

In[45]:= Cases[list, {_, _?(# > 3 &), ___}]
Out[45]= {{5, 6, 7, 8}}

我怀疑这会比 Select 更快，但有时会更清晰，特别是如果测试涉及不同的数据类型或匹配某些子结构。

Answer 5

编辑：

正如 Alexey 所说，以下结构在 Mathematica 中比我之前的解决方案更惯用

Cases[list, x_List /; x[[2]] > 2]

和

Cases[list, _List?(#[[2]] > 2 &)]

---

一种解决方案是使用Cases

Cases[list, {_, x_, ___} /; x > 2]
Out[1] = {{5, 6, 7, 8}}

如果您想（比如说）检查第 95 个元素是否 > 2，这将没有帮助。所以这是一种更好的方法，您可以轻松地指定位置：

Cases[list, {x___} /; List[x][[2]] > 2]
Out[2] = {{5, 6, 7, 8}}