通过子目录将 .wav 文件批量转换为 .mp3 文件，然后删除剩余的 .wav 文件

Question

我在一个广播电台工作，我们使用一个名为 Skimmer Plus 的程序进行音频记录，该程序从我们的父目录“Air Check”创建多个子目录，目录树如下所示（降序）：

空气检查
年份（所以现在应该是 2016 年）
月份（11 月）
第（22）天

并且.wav文件保存在Day目录中，但是没有任何其他目录保存文件，只是在“Day”目录中。

我正在努力首先将 .wav 文件自动转换为 .mp3 文件。现在我只使用lame dropper“lamedropXPd3-64.exe”，但我也下载了“lame.exe”，如果这样可以更容易使用的话。这是我尝试使用自动转换的代码：

@echo off
PushD for %%i in (*.wav) do "\\wideorbit.byui.edu\d\Radio Productions\Air Check\2016\November\22" -V 6 --vbr-old --resample 22.05 "%%i" "%%~ni.mp3" & PopD
pause

我得到的错误信息是：“文件名、目录名或卷标语法不正确。”

这是我的第一个问题。

第二个问题（删除剩余的 .wav 文件以节省空间）我离工作更近了。这是我的代码：

@echo off
PushD "\\wideorbit.byui.edu\d\Radio Productions\Air Check\2016\November\22" &&(forfiles -m *.wav* -d -0 -c "cmd /c del /s /q @path") & PopD
pause

这可以删除所有文件，但正如您所见，它只会影响那天。我希望它从这里开始工作：

@echo off
PushD "\\wideorbit.byui.edu\d\Radio Productions\Air Check\" &&(forfiles -m *.wav* -d -0 -c "cmd /c del /s /q @path") & PopD
pause

但是当我尝试运行它时，我收到以下错误消息： “错误：没有找到符合指定搜索条件的文件。”

我可以对代码的两个部分进行哪些更改以使其完全可操作？

（另外，我将@echo off 和pause 放在那里以便于测试，当我一起完成最终程序时，我会将它们取出）。

谢谢！

Answer 1

为了汇总一些不错的技巧，这批将默认扫描当前文件夹中的 .wav 文件。但是有可选的命令行参数可以从Base 到/FullScan 或当前的/Year 或/Month 向下扫描整个树。

Lame 和 Del 命令只有 Echoed，只要两个 echo 命令位于倒数第二行。

:: Wav2mpg.cmd
@Echo off & SetLocal EnableExtensions EnableDelayedExpansion
Set Lame="X:\Path\to\your\lame.exe"
Set LameOpts= -V 6 --vbr-old --resample 22.05
Set "Base=\\wideorbit.byui.edu\d\Radio Productions\Air Check"

:: Get current Date
For /f "tokens=1-3 delims=.+-" %%A in (
  'wmic os get LocalDateTime^|findstr ^^[0-9]'
) do Set _DT=%%A
Set "year=%_DT:~0,4%"&Set "Month=%_DT:~4,2%"&Set "Day=%_DT:~6,2%"
:: Strip leading zero from Month, Get Monthname
set /a Mo=100%Month%%%100
For /f "tokens=%Mo%" %%A in (
  'echo/January February March April May June^
   July August September October November December'
) do set MonthName=%%A

If /i "%~1" Equ "/FullScan" Goto :Skipover
If /i "%~1" Equ "/Year"  Set Base=%Base%\%Year%
If /i "%~1" Equ "/Month" Set Base=%Base%\%Year%\%MonthName%
If /i "%~1" Equ "" Set Base=%Base%\%Year%\%MonthName%\%Day%

:skipover
PushD "%Base%" || (Echo couldn't pushd %Base%&Pause&Exit /B 1)
For /f  "delims=" %%A in (
  'Dir /B/S/A-D .\*.wav'
) Do Echo %Lame% %LameOpts% "%%~fA" "%%~dpnA.mp3" && Echo Del "%%~fA"
PopD

Answer 2

@echo off
PushD
for %%i in (*.wav) do someexecutablenameherwouldbehelpfulIthink "\\wideorbit.byui.edu\d\Radio Productions\Air Check\2016\November\22" -V 6 --vbr-old --resample 22.05 "%%i" "%%~ni.mp3"
PopD
pause

Answer 3

要将目录树中的所有.wav 文件转换为.mp3 文件，您可以使用以下代码：

pushd "\\wideorbit.byui.edu\d\Radio Productions\Air Check" || exit /B 1
for /R %%F in ("*.wav") do (
    pushd "%%~dpF" && (
        lame -V 6 --vbr-old --resample 22.05 "%%~nxF" "%%~nF.mp3" && (
            del "%%~nxF"
        )
        popd
    )
)
popd

要转换今天的.wav 文件（或者更准确地说是今天修改日期的文件，不检查父目录名称），您可以使用以下代码：

pushd "\\wideorbit.byui.edu\d\Radio Productions\Air Check" || exit /B 1
for /F "delims=" %%F in ('
    forfiles /S /M "*.wav" /D +0 /C "cmd /C echo @path"
') do (
    pushd "%%~dpF" && (
        lame -V 6 --vbr-old --resample 22.05 "%%~nxF" "%%~nF.mp3" && (
            del "%%~nxF"
        )
        popd
    )
)
popd

请注意，对于这两种方法，成功转换的 .wav 文件随后会被删除。

Answer 4

只能推荐“EZ CD Audio Converter”，使用多年，非常兴奋，用于转换（也可以一次性删除）。不贵，一分钱一分货。提供 30 天免费试用。

对于组织、移动、标记，我推荐“mp3tag”。可以批量工作并标记和移动文件。很棒的免费软件，但要发挥全部潜力，您必须学习语法。