替换列表中元素的方案过程

Question

我正在尝试在方案中创建一个过程，用另一个元素替换列表中的某个元素

(define (replace var player list)
  (if (null? list)
      '()
     (if (list? (car list))
                (cons (replace var player (car list))          
                      (replace var player (cdr list))
          (if (equal? var (car list))
              (cons player (replace var player (cdr list)))
              (cons (car list) (replace var player (cdr list)))
          ))))

目前该过程不替换任何元素。 这是输入列表

'(q w (e r (t x)) y u i (o (x)) p x a s d)

我想将该列表中的“x”元素替换为“y”。

这是想要的输出

'(q w (e r (t y)) y u i (o (y)) p y a s d)

我们已经尝试过

(replace_by 'x 'y '(q w (e r (t x)) y u i (o (x)) p x a s d) 

但它似乎不起作用

Answer 1

发布的代码末尾缺少一个括号，并且括号放错了位置。第一个cons 表达式需要用括号括起来：

(define (replace var player list)
  (if (null? list)
      '()
     (if (list? (car list))
         (cons (replace var player (car list))          
               (replace var player (cdr list)))
         (if (equal? var (car list))
             (cons player (replace var player (cdr list)))
             (cons (car list) (replace var player (cdr list)))))))

在这些更正之后，OP 代码适用于要替换的项目是非列表的嵌套列表。但是，当要替换的项目是列表时，它会失败。这是因为输入中遇到的列表元素永远不会与var 进行相等性检查。另请注意，在 Scheme 函数中使用 list 作为形式参数是个坏主意；这会影响内置的 list 函数。

这是一个将替换输入列表中的原子和列表的实现。在检查输入是否为原子之前，该函数会检查与old 是否相等。如果old 值不是equal? 到当前head 值，则该函数检查当前head 值是否是原子。如果是，那么那个原子（不是equal? 到old）被限制在tail 上调用replace 的结果上；请注意，空列表被视为原子（'() 既是列表 又是 原子）并且在此阶段已经处理。否则，当前head 是一个非空列表，并且该函数下降到head 和tail。

这里atom? 用于区分非空列表和原子，'() 被视为原子。一些方案包含atom? 的定义，但它不在 R5RS 或 R6RS 标准方案中。如果需要，您可以自己定义：

(define (atom? x)
  (not (pair? x)))

或者您可以在下面的代码中使用(not (pair? head)) 代替(atom? head)，它使用atom?，因为名称似乎更具描述性。 let 表达式用于减少对car 和cdr 的调用次数，并阐明对replace 的递归调用的意图：

(define (replace old new xs)
  (if (null? xs)
      xs
      (let ((head (car xs))
            (tail (cdr xs)))
        (cond ((equal? head old)
               (cons new (replace old new tail)))
              ((atom? head)
               (cons head (replace old new tail)))
              (else
               (cons (replace old new head)
                     (replace old new tail)))))))

以下是一些交互示例：

> (replace 'a 'x '(1 2 a 3 4 a))
(1 2 x 3 4 x)

> (replace 'a 'x '(1 2 a (3 4 a (5 a (a (a)) 6 a) ()) a))
(1 2 x (3 4 x (5 x (x (x)) 6 x) ()) x)

> (replace '() 'x '(1 2 a (3 4 a (5 a (a (a)) 6 a) ()) a))
(1 2 a (3 4 a (5 a (a (a)) 6 a) x) a)

> (replace '(5 a (a (a)) 6 a) 'x '(1 2 a (3 4 a (5 a (a (a)) 6 a) ()) a))
(1 2 a (3 4 a x ()) a)

> (replace '(5 a (a (a)) 6 a) '(x (x x)) '(1 2 a (3 4 a (5 a (a (a)) 6 a) ()) a))
(1 2 a (3 4 a (x (x x)) ()) a)