如何在 Guile Web 服务器中读取 POST 数据

Question

在 Guile 的网络服务器中，我似乎找不到任何有关读取 POST 数据的文档。它似乎与“请求”一起作为“正文”发送到我的入口点函数。看起来 body 被编码为字节向量，我可以将其解码为字符串：

(use-modules (rnrs bytevectors))
(utf8->string body)

所以我可以从这里开始解析字符串，但这似乎相当乏味且容易出错。有没有办法以某种列表的形式读取 POST 数据？

Answer 1

这是decode 过程的代码，它将BODY 转换为列表的关联列表，其中键是表单字段的名称，值是与该键关联的值的列表。请注意，decode 返回的关联中与给定键关联的“值”始终是一个列表。

(define-module (web decode))

(use-modules (ice-9 match))
(use-modules (rnrs bytevectors))
(use-modules (srfi srfi-1))
(use-modules (srfi srfi-26))
(use-modules (web uri))

;;;
;;; decode
;;;

(define (acons-list k v alist)
  "Add V to K to alist as list"
  (let ((value (assoc-ref alist k)))
    (if value
        (let ((alist (alist-delete k alist)))
          (acons k (cons v value) alist))
        (acons k (list v) alist))))

(define (list->alist lst)
  "Build a alist of list based on a list of key and values.

   Multiple values can be associated with the same key"
  (let next ((lst lst)
             (out '()))
    (if (null? lst)
        out
        (next (cdr lst) (acons-list (caar lst) (cdar lst) out)))))

(define-public (decode bv)
  "Convert BV querystring or form data to an alist"
  (define string (utf8->string bv))
  (define pairs (map (cut string-split <> #\=)
                     ;; semi-colon and amp can be used as pair separator
                     (append-map (cut string-split <> #\;)
                                 (string-split string #\&))))
  (list->alist (map (match-lambda
                      ((key value)
                       (cons (uri-decode key) (uri-decode value)))) pairs)))