如何从 Common Lisp 中的宏参数创建一个单词？ [复制]

Question

我有：

(defmacro test (a b c)
    `'(,a ,b ,c))

按预期运行(test apple banana cuba) 会得到(APPLE BANANA CUBA)。

如何让宏生成APPLEBANANACUBA？

我试过了：

(defmacro test (a b c)
        `'(,a,b,c))

但运行(test ant bites chris) 仍然返回(ANT BITES CHRIS) 作为三个单独参数的列表。

我尝试了各种变化，但似乎都没有。喜欢这个：

(defmacro test (a b c)
    `(apply #'concatenate 'symbol '(,a ,b ,c)))

显然，这会出错，因为 'symbol 不是连接的有效输出类型。

我确信这是我对宏如何工作的一些基本误解，并且有一种简单的方法可以做到这一点。我错过了什么？

Answer 1

将它们连接成一个字符串，然后从该字符串创建一个符号。

(defmacro test (a b c)
  (intern (concatenate 'string a b c)))

INTERN 将实习生当前包中的字符串，您也可以使用MAKE-SYMBOL 创建一个非实习符号。

Answer 2

对宏及其实现的困惑

我确信这是我对宏如何工作的一些基本误解

是的：

• 宏和创建“词”是完全独立的正交概念。

• Lisp 中不存在“单词”的概念。但是有符号、字符串、数字……

• 如果您想到APPLEBANANACUBA，那么您可能指的是一个符号。

解决问题

1. 首先解决如何从符号列表中创建符号的问题
2. 实现宏

如果你想创建一个新的符号，它是符号的串联，那么你需要：

1. 获取符号，将它们的名称作为字符串
2. 创建一个字符串，将这些名称串联起来
3. 从该字符串创建一个符号，可能在一个包中。

内爆操作

我们称这个操作为implode，这是它的历史名称：

(defun implode-symbols (symbols &optional (package *package*))
  (when symbols
    (values
     (intern (with-output-to-string (stream)
               (dolist (symbol symbols)
                 (write-string (symbol-name symbol) stream)))
             package))))


CL-USER 30 > (implode-symbols '(a - b - c - foo - bar))
A-B-C-FOO-BAR

现在，可以制作一个更通用的版本，它可以内爆所有东西：

(defun implode (things)
  (when things
    (values
     (intern (with-output-to-string (stream)
               (dolist (thing things)
                 (princ thing stream)))))))

CL-USER 31 > (implode '(a - b - c - foo :bar - 42 - "BAZ"))
A-B-C-FOOBAR-42-BAZ

一个内爆一些参数的宏

鉴于我们有一个从事物列表中创建符号的函数，我们可以轻松编写宏：

CL-USER 37 > (defmacro test (a b c)
               `',(implode (list a b c)))
TEST

CL-USER 38 > (macroexpand-1 '(test foo bar baz))
(QUOTE FOOBARBAZ)
T

CL-USER 39 > (test foo bar baz)
FOOBARBAZ

原子，内爆和爆炸

符号是原子。这意味着它们不是 cons 单元，后者是链表的基本构建块。

你可以爆炸和内爆一个原子，这里是一个符号。

• 内爆符号FOO和BAR -> FOOBAR
• 分解符号FOOBAR -> F, O, O, B, A, R