有限列表的haskell内存不足

Question

我在尝试运行诸如此类的中等输入时内存不足：

variation_models 15 25

同时为 ncars 运行更高的数字似乎在速度和内存使用方面产生了巨大差异。

预计会放缓（有更多的东西要比较），但内存使用量的指数增长对我来说没有意义

import Control.Monad

orderedq f [] = True
orderedq f (x:[]) = True
orderedq f (x:y:zs) = f x y && orderedq f (y:zs)

num_orderedq = orderedq (<=)

adds_up_to n xs = n == sum xs

both_conditions f g xs = f xs && g xs

variation_models ncars nlocations =
  filter (both_conditions (adds_up_to nlocations) num_orderedq) $ replicateM ncars [1..nlocations-ncars+1]

是什么导致了内存使用量的巨大差异？ replicateM?

Answer 1

我认为您在其他地方已经看到，您的特定问题（创建总和为给定数字的整数的有序列表）可以使用替代算法更好地解决，而不是过滤大量整数列表。

但是，回到你原来的问题，可以构造一个等价的：

replicateM p [1..n]

以指数时间运行（当然）但空间恒定。

问题是这个表达式或多或少等价于递归：

badPower 0 _ = pure []
badPower p n = [x:xs | x <- [1..n], xs <- badPower (p-1) n]

因此，在列表推导中，对于每个选定的x，整个列表badPower (p-1) n 需要从头开始重新生成。 GHC 明智地决定保留badPower (p-1) n，这样就不需要每次都重新计算。因此，badPower p n 调用需要将整个badPower (p-1) n 列表保存在内存中，这已经考虑了n^(p-1) 元素和指数内存使用，即使不考虑badPower (p-2) n 等。

如果你只是翻转隐式循环的顺序：

goodPower 0 _ = pure []
goodPower p n = [x:xs | xs <- goodPower (p-1) n, x <- [1..n]]

这解决了问题。即使列表goodPower (p-1) n 是“大”的，我们还是取它的第一个元素，对x 的每个值使用它n 次，然后可以丢弃它并移至下一个元素。因此，goodPower (p-1) n 可以在使用时进行垃圾回收。

注意goodPower 生成元素的顺序与badPower 不同，列表的第一个坐标变化最快，而不是最后一个。 （如果这很重要，您可以map reverse $ goodPower ...。虽然reverse 是“慢”，但它仅适用于此处的短名单。）

无论如何，以下程序（实际上）永远运行，但在恒定空间中运行：

power :: Int -> [a] -> [[a]]
power 0 _ = [[]]
power p lst = [x:xs | xs <- power (p-1) lst, x <- lst ]

main = do
  print $ length (power 15 [1..11])

Answer 2

replicateM :: Applicative m => Int -> m a -> m [a] 

当 'm' 为 [] 时，monad join 实现将使 replicateM 从列表元素中构建 n 个元素的所有排列。这种排列的数量写成 P(n,k)，等于 n!/(n-k)!。这就是指数级增长的来源。