是否可以检查是否从 Jenkins 声明性管道中的特定存储库签出？

Question

我想在我的 Jenkinsfile 中有一个发布阶段，它只在从原始存储库中签出时运行。这是为了避免在克隆存储库上出现错误消息，因为那里缺少密钥等。

stage('Release')
 {
  when
   {
    allOf 
     {
      // TODO Check for repository url https://github.com/PowerStat/TemplateEngine.git
      branch 'master'
     }
   }
  steps
   {
    script
     {
      if (isUnix()) 
       {           
        sh 'mvn --batch-mode release:clean'
        sh 'mvn --batch-mode release:prepare'
        sh 'mvn --batch-mode release:perform'
       }
      else
       {
        bat 'mvn --batch-mode release:clean'
        bat 'mvn --batch-mode release:prepare'
        bat 'mvn --batch-mode release:perform'
       }
     }
   }
 }

我学习了Pipeline Syntax: when，但不知道如何进行我想要的测试。

我也想过使用环境变量Global Variable Reference，但发现其中没有存储库URL。

所以我的问题是：如何在声明式管道中实现此检查？

Answer 1

您可以从git config remote.origin.url 命令获取远程存储库 URL。您可以使用 when 块内的 expression 指令执行此命令 - 它定义了一个返回 boolean 值的闭包。

考虑以下示例：

def expectedRemoteUrl = "https://github.com/PowerStat/TemplateEngine.git"

pipeline {
    agent any

    stages {
        stage("Release") {
            when {
                allOf {
                    branch 'tmp'
                    expression {
                        def remoteUrl = isUnix() ?
                            sh(script: "git config remote.origin.url", returnStdout: true)?.trim() :
                            bat(script: "git config remote.origin.url", returnStdout: true)?.trim()

                        return expectedRemoteUrl == remoteUrl
                    }
                }
            }

            steps {
                echo "Do your release steps here..."
            }
        }
    }
}

或者，如果git 命令在运行管道的节点中不可用，您可以使用scm.userRemoteConfigs?.first()?.url 获取远程存储库 URL。考虑以下示例：

def expectedRemoteUrl = "https://github.com/PowerStat/TemplateEngine.git"

pipeline {
    agent any

    stages {
        stage("Release") {
            when {
                allOf {
                    branch 'tmp'
                    expression {
                        def remoteUrl = scm.userRemoteConfigs?.first()?.url

                        return expectedRemoteUrl == remoteUrl
                    }
                }
            }

            steps {
                echo "Do your release steps here..."
            }
        }
    }
}