如何使用 proc compare 来更新数据集

Question

我想使用proc compare 每天更新数据集。

work.HAVE1

Date        Key Var1 Var2 
01Aug2013   K1   a    2
01Aug2013   K2   a    3
02Aug2013   K1   b    4

work.HAVE2

Date        Key Var1 Var2 
01Aug2013   K1   a    3
01Aug2013   K2   a    3
02Aug2013   K1   b    4
03Aug2013   K2   c    1

Date和Key是唯一确定一条记录。 如何使用上面的两个表来构造如下

work.WANT

Date        Key Var1 Var2 
01Aug2013   K1   a    3
01Aug2013   K2   a    3
02Aug2013   K1   b    4
03Aug2013   K2   c    1

我不想删除以前的数据然后重新构建它。我想通过在底部追加新记录来modify 它并调整VAR1 或VAR2 中的值。 我正在为proc compare 苦苦挣扎，但它并没有返回我想要的。

Answer 1

proc compare base=work.HAVE1 compare=work.HAVE2 out=WORK.DIFF outnoequal outcomp;
id Date Key;
run;

这将在单个数据集 WORK.DIFF 中为您提供新的和更改的（不相等的记录）。你必须自己区分新的和改变的。

但是，您想要实现的实际上是 MERGE - 插入新的，覆盖现有的，尽管可能由于性能原因等。您不想重新创建完整的表。

data work.WANT;
    merge work.HAVE1 work.HAVE2;
    by Date Key;
run;

编辑1：

/* outdiff option will produce records with _type_ = 'DIF' for matched keys */
proc compare base=work.HAVE1 compare=work.HAVE2 out=WORK.RESULT outnoequal outcomp outdiff;
id Date Key;
run;


data WORK.DIFF_KEYS;  /* keys of changed records */
    set WORK.RESULT;
    where _type_ = 'DIF';
    keep Date Key;
run;

/* split NEW and CHANGED */
data
    WORK.NEW
    WORK.CHANGED
;
 merge
      WORK.RESULT (where=( _type_ ne 'DIF'));
        WORK.DIFF_KEYS (in = d)
    ;
  by Date Key;
  if d then output WORK.CHANGED;
  else output WORK.NEW;
run;

编辑2：

现在您可以将APPEND WORK.NEW 用于目标表。

对于 WORK.CHANGED - 使用 MODIFY 或 UPDATE 语句更新记录。 根据更改的大小，您还可以考虑PROC SQL; DELETE 删除旧记录，PROC APPEND 添加新值。

Answer 2

所有 PROC COMPARE 都会告诉您 2 个数据集之间的差异。要实现您的目标，您需要在数据步骤中使用 UPDATE 语句。这样，HAVE1 中的值将使用日期和键匹配的 HAVE2 进行更新，或者如果没有匹配项则插入新记录。

data have1;
input Date :date9. Key $ Var1 $ Var2;
format date date9.;
datalines;
01Aug2013   K1   a    2
01Aug2013   K2   a    3
02Aug2013   K1   b    4
;
run;

data have2;
input Date :date9. Key $ Var1 $ Var2;
format date date9.;
datalines;
01Aug2013   K1   a    3
01Aug2013   K2   a    3
02Aug2013   K1   b    4
03Aug2013   K2   c    1
;
run;

data want;
update have1 have2;
by date key;
run;