循环通过工作表删除重复项

Question

我的代码似乎工作正常。我想检查改进、潜在错误和意外后果。

我有包含重复信息的电子表格，有些电子表格每个文件中有 100 张。

我不想使用删除重复信息手动浏览每张工作表。

经过搜索，我认为我有一个解决方案。

Sub RemoveDuplicates()
 ' RemoveDuplicates Macro
 ' Selects all values then removes duplicates
 '

     ' Declare Current as a worksheet object variable.
         Dim Current As Worksheet
         Dim starting_ws As Worksheet
         Set starting_ws = ActiveSheet 'remember which worksheet is active in the beginning

         ' Loop through all of the worksheets in the active workbook.
         For Each Current In Worksheets
            Current.Activate
            
            LastRow = Cells(Rows.Count, "A").End(xlUp).Row
            ActiveSheet.Range("A1" & LastRow).RemoveDuplicates Columns:=Array(1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11), Header:=xlYes
      
         Next
         
    starting_ws.Activate 'activate the worksheet that was originally active
    
End Sub

我只在每张工作表上寻找重复项，而不是比较工作表。列数也将保持不变。

Answer 1

删除重复项（多列和工作表）

• 使用Option Explicit。
• 这个ActiveSheet.Range("A1" & LastRow) 肯定是错的。考虑一下。
• 您必须符合Range、Cells、Rows 和Columns 的条件，例如Current.Cells, Current.Rows.Count...
• 您不必激活Current。 Current 在您的情况下是 ActiveSheet（因为您已激活它），因此无需使用 ActiveSheet 代替。
• 不要让Excel 定义范围：您自己定义。

带问题的代码

Option Explicit

Sub removeDupes()
     
     ' Here's a question:
     '     Why can't I use 'Cols' instead of the array written explicitly?
     Dim Cols As Variant
     Cols = Array(1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11)
     
     Const FirstAddress As String = "A1"
     Dim wb As Workbook
     Set wb = ActiveWorkbook
     
     Dim ws As Worksheet
     Dim LastCell As Range
     
     For Each ws In wb.Worksheets
         Set LastCell = ws.Cells(ws.Rows.Count, "A").End(xlUp).Offset(, 10)
         ws.Range(FirstAddress, LastCell).RemoveDuplicates _
             Columns:=Array(1, 2, 3, 4, 5, 6, 7, 8, 9, 10, 11), Header:=xlYes
         ' This doesn't work.
         'ws.Range(FirstAddress, LastCell).RemoveDuplicates _
             Columns:=Cols, Header:=xlYes

         ' Try this with ByVal array.
         'ws.Range(FirstAddress, LastCell).RemoveDuplicates _
             Columns:=(Cols), Header:=xlYes
     Next

End Sub