范围链接到相邻列中的最后一个单元格

Question

我有一个包含 4 列的工作表，我编写了一个宏来将公式放在 A + B 列中，这取决于 D 列中的内容，然后复制并粘贴为值以启用对这些列的过滤。我的问题是每周 D 列会变长。我不想在我的宏中不断更改 A + B (A2:A69422) 范围内的值，其中 69422 是 D 列中最后使用的单元格。

Worksheets("salesinfo").Range("B2").Formula = "= MID(D3,3,5)"
    Range("B2").Select
        Selection.AutoFill Destination:=Range("B2:B69422")
        Range("B2:B69422").Select
        Selection.Copy
        Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
            :=False, Transpose:=False

    Selection.Value = Selection.Value

    Range("A2").Formula = "= VLOOKUP(B2,[Data.xlsb]Stores!$A:$X,4,0)"

    Range("A2").Select
        Selection.AutoFill Destination:=Range("A2:A69422")
        Range("A2:A69422").Select
        Selection.Copy
        Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
            :=False, Transpose:=False

            Workbooks("Data.xlsb").Close SaveChanges:=False

            Application.CutCopyMode = False

            Range("A2").Select

Answer 1

使用以下语法确定 D 列中的最后一行，然后将其分配给 Long 或 Integer 变量。在我的示例中，我使用 lRow 作为我的变量：

Dim lRow As Long

With ActiveSheet

    lRow = .Cells(.Rows.Count, 4).End(xlUp).Row

End With

然后只需在单元格地址的行引用中使用lRow + 1。

Answer 2

正如TheGuyThatDoesn'tKnowMuch 所指出的，声明一个 Long 类型变量并存储模式相关列的最后填充行最好通过自下而上来完成。这相当于从工作表底部开始并点击 Ctrl+▲。

这里有一些其他方法可以改进您的代码。

• 使用With ... End With statement 定义您的Workbook Object 和Worksheet Object，并通过为每个Range object 加上. 前缀来使用该引用，例如.Range(...)。不要隐含 .Parent 工作表引用；总是让他们明确。
• 一次编写所有公式；无需使用Range.AutoFill method。
• 直接值传输比复制和粘贴特殊值更有效，并且不涉及剪贴板。
• 避免使用Range.Select 和Range.Activate 方法¹。它们可能是开始使用 VBA 的好方法，但它们也是您毕业时应该离开的第一件事。
  

当您只需要 A:D 时，在 VLOOKUP function 内的外部工作簿中引用列 A:X 效率低下；无论如何，对于大量行，INDEX/MATCH 函数对可能会更好。

您正在将公式写入引用外部工作簿 Data.xlsb 的 A 列，所以我知道这不是包含 salesinfo 工作表的工作表。您应该调整下面的工作簿参考以避免使用ActiveWorkbook property。

    Dim lr As Long

    With ActiveWorkbook
        With .Worksheets("salesinfo")
            lr = .Cells(.Rows.Count, "D").End(xlUp).Row
            With .Range("B2:B" & lr)
                .Formula = "=MID(D3, 3, 5)"
                .Value = .Value
            End With
            With .Range("A2:A" & lr)
                .Formula = "=VLOOKUP(B2, [Data.xlsb]Stores!$A:$X, 4, FALSE)"
                'alternate formula
                '.Formula = "=INDEX([Data.xlsb]Stores!$D:$D, MATCH(B2, [Data.xlsb]Stores!$A:$A, 0))"
                .Value = .Value
            End With
            .Range("A2").Activate
        End With
    End With

    Workbooks("Data.xlsb").Close SaveChanges:=False

用于 B 列的公式让我有点担心。您从 B2 的公式中引用 D3。这意味着如果将公式填充到 B 列以匹配 D 列中的所有值，则最后一个公式实际上将引用 D 列中最后一个填充单元格下方的空白单元格。

如果您在将两列公式写入近 70K 行时遇到计算滞后问题（耗时太长），字典对象和变量数组可以显着加快速度。

---

.¹ _{请参阅How to avoid using Select in Excel VBA macros，了解更多摆脱依赖选择和激活来实现目标的方法。}