用列文本替换文本标记

Question

我有几列文字。此外，我还有一个名为Replacement text 的专栏。此列包含带有标记的字符串，例如 [1], [2], etc.

我想用标记所在行中的文本替换标记。

例如，Here you can find [5] 变为 Here you can find b，因为[5] 是标记列，而字符串行中的b 是标记的值。

我正在考虑创建一个大的if-else 构造和substitute 文本，这非常容易出错。

但是，请问您是否有更简单的解决方案？

感谢您的意见！

Answer 1

此答案高度抄袭 Thomas Inzina 的第一版答案，但执行替换的一种非常简单的方法是：

Sub ReplaceText()
    Dim r As Long
    Dim c As Long
    With ActiveSheet
        For r = 3 To .Range("K" & .Rows.Count).End(xlUp).Row
            For c = 1 To 10
                .Cells(r, "K").Replace "[" & c & "]", .Cells(r, c).Value
            Next
        Next
    End With
End Sub

以上代码将尝试使用所有十个列进行替换。

正如 Thomas 所指出的，以下代码仅在需要替换时才会执行替换，因此速度可能会快一个数量级，因此无疑是一个更好的解决方案：

Sub ReplaceText()
    Dim r As Long
    Dim c As Long
    With ActiveSheet
        For r = 3 To .Range("K" & .Rows.Count).End(xlUp).Row
            For c = 1 To 10
                If Instr(.Cells(r, "K").Value, "[" & c & "]") > 0 Then
                    .Cells(r, "K").Replace "[" & c & "]", .Cells(r, c).Value
                End If
            Next
        Next
    End With
End Sub

（非常感谢 Thomas 为对两种不同方法进行速度测试所做的努力。）

Answer 2

ReplaceBrackets1：使用 RegEx 提取列号。处理 10 万条记录需要 15.03 秒。

---

Sub ReplaceBrackets1()
    'http://analystcave.com/excel-regex-tutorial/
    Dim c As Range
    Dim Match As Object, Matches As Object, regex As Object
    Set regex = CreateObject("VBScript.RegExp")

    With regex
        .Global = True
        .Pattern = "\[(.*?)\]"
    End With

    For Each c In Range("K3", Range("K" & Rows.Count).End(xlUp))
        If regex.Test(c.Text) Then
            Set Matches = regex.Execute(c.Text)
            For Each Match In Matches
                c.Replace Match, c.EntireRow.Columns(CInt(Match.SubMatches(0)))
            Next Match

        End If
    Next
End Sub

ReplaceBrackets2：将数据加载到数组中，使用 RegEx 提取列号，并且只写入工作表 1 次。处理 10 万条记录需要 1.27 秒。

---

Sub ReplaceBrackets2()
'http://analystcave.com/excel-regex-tutorial/
    Dim x As Long, column As Long
    Dim arData, values
    Dim Match As Object, Matches As Object, regex As Object
    Set regex = CreateObject("VBScript.RegExp")

    With regex
        .Global = True
        .Pattern = "\[(.*?)\]"
    End With

    values = Range("K3", Range("K" & Rows.Count).End(xlUp))
    arData = Range("A3", "L" & UBound(values, 1) + 2)

    For x = 1 To UBound(values, 1)
        If regex.Test(values(x, 1)) Then
            Set Matches = regex.Execute(values(x, 1))
            For Each Match In Matches
                column = Match.SubMatches(0)
                values(x, 1) = arData(x, column)
            Next Match
        End If
    Next

    Range("K3", Range("K" & Rows.Count).End(xlUp)) = values

End Sub

在将ReplaceBrackets1 转换为UDF (getReplacedText) 后，我惊讶地发现只需 2.53 秒即可为 10 万条记录填写公式。我不确定这会比原来的更快。但是有这么多公式确实会减慢电子表格的速度。

getReplacedText：使用静态正则表达式解析数据。

Function getReplacedText(ReplacementText As String, Source As Range)
'http://analystcave.com/excel-regex-tutorial/
    Dim Match As Object, Matches As Object
    Static regex As Object
    If regex Is Nothing Then
        Set regex = CreateObject("VBScript.RegExp")

        With regex
            .Global = True
            .Pattern = "\[(.*?)\]"
        End With
    End If

    If regex.Test(ReplacementText) Then
        Set Matches = regex.Execute(ReplacementText)
        For Each Match In Matches
            ReplacementText = Replace(ReplacementText, Match, Source.Columns(CInt(Match.SubMatches(0))))
        Next Match

    End If

    getReplacedText = ReplacementText
End Function