使用 IF 和 VLOOKUP 函数的 Excel 公式答案

【问题标题】：Excel Formula using IF and VLOOKUP Function使用 IF 和 VLOOKUP 函数的 Excel 公式
【发布时间】：2018-06-06 15:58:11
【问题描述】：

上下文

我正在尝试使用 Sheet2 中的数据更新 Sheet1 中的新球员名单。但是，我试图只更新男性花名册信息。我必须首先验证它是一个新玩家并且他们是男性才能更新身高。

我应用的逻辑是 IF 你找到了“是”，而 VLOOKUP 返回了“男性”，那么单元格应该填充一个公式，然后在 VLOOKUP 中使用 ID #。

EXCEL 示例

*=IF(VLOOKUP("Yes",Sheet2!C2:D6, 2, FALSE) ="Male", "=VLOOKUP(A3, Sheet2!A2:D10, 2, FALSE)", "No")

Sheet1                                         Sheet2
ID #      Height                          ID#   Height      New       Gender    
100         No                            100    66"         No        Female      
101         *                             101    72"         Yes       Male       
102         No                            102    65"         Yes       Female

问题

* 的输出是单元格中的=VLOOKUP(A3, Sheet2!A2:D10, 2, FALSE)。有没有办法让 Excel 像原来的公式一样实际评估和填充该单元格？

【问题讨论】：

使用INDIRECT函数
@PeterT 你能提供更多细节吗？

标签： excel excel-formula vlookup

【解决方案1】：

由于您要查找多个条件，请改用 INDEX 和 MATCH：

=IFERROR(INDEX(Sheet2!$B$2:$B$4,MATCH(A3&"YesMale",INDEX(Sheet2!$A$2:$A$4&Sheet2!$C$2:$C$4&Sheet2!$D$2:$D$4,),0)),"No")

【讨论】：

【解决方案2】：

你可以简单地把它从引号中去掉，但即使那样我也不认为你会得到你想要的。

试试这个：

= IF(
    AND(
        VLOOKUP(A3, Sheet2!$A$2:$D$10, 3, FALSE) = "Yes",
        VLOOKUP(A3, Sheet2!$A$2:$D$10, 4, FALSE) = "Male"),
    VLOOKUP(A3, Sheet2!$A$2:$D$10, 2, FALSE),
    "No")

【讨论】：