EInsufficientRTTI 异常，带有消息“RTTi 不足，无法支持此操作”

Question

尝试在运行时将对象转换为 JSON，但出现 RTTI 不足错误。 对象是：

{$M+}
{$TYPEINFO ON}
{$METHODINFO ON}
{$RTTI EXPLICIT METHODS([vcPublic, vcPublished]) PROPERTIES([vcPublic, vcPublished])}

TMyPacket = class(TObject)
  Private
    FID: TGUID;
    FToIP: string;
    FToPort: integer;
    FSent: boolean;
    FSentAt: TDateTime;
    FAck: boolean;
    FTimeOut: Cardinal;
    FDataToSendSize: UINT64;
    FDataToSend: AnsiString;
  public
    constructor create;
    destructor free;
  published
    property ID: TGUID read FID write FID;
    property ToIP: string read FToIP write FToIP;
    property ToPort: integer read FToPort write FToPort;
    property Sent: boolean read FSent write FSent;
    property SentAt: TDateTime read FSentAt write FSentAt;
    property Ack: boolean read FAck write FAck;
    property TimeOut: Cardinal read FTimeOut write FTimeOut;
    property DataToSend: AnsiString read FDataToSend write FDataToSend;
  end;

后面的代码：

var fpacket: TMYPacket;
begin     
fpacket := TVWTCPPacket.create;
//assign value to class properties
memo1.Lines.Text := TJson.ObjectToJsonString(fpacket); //throws error

并收到 JSON 转换错误。 有人知道 Delphi Berlin 10.1 出了什么问题吗？ 我确实记得 XE2 上的一些 RTTI 问题，但不确定上面发生的事情是否与 Delphi 旧错误有关。

Answer 1

进入System.Rtti 并在if ft = nil then 行处将断点放入TRttiField.GetValue 并设置断点条件ft = nil（如果您将断点放在下一行中，您将无法看到该字段的名称是因为优化）。

当您的调试器停在那里时，您可以检查Self.Name (Ctrl+F7)，它会告诉您D4，这是您的 TGuid 的第四个字段。这是因为 JsonReflect 通过序列化它们的字段来递归地序列化记录。因为D4 被声明为array[0..7] of Byte 它不包含类型信息（see also）。

要解决此问题，请为 TGUID 创建您自己的类型拦截器：

type
  TGuidInterceptor = class(TJSONInterceptor)
  public
    function StringConverter(Data: TObject; Field: string): string; override;
    procedure StringReverter(Data: TObject; Field: string; Arg: string); override;
  end;

function TGuidInterceptor.StringConverter(Data: TObject;
  Field: string): string;
var
  ctx: TRttiContext;
begin
  Result := ctx.GetType(Data.ClassInfo).GetField(Field).GetValue(Data).AsType<TGuid>.ToString;
end;

procedure TGuidInterceptor.StringReverter(Data: TObject; Field, Arg: string);
var
  ctx: TRttiContext;
begin
  ctx.GetType(Data.ClassInfo).GetField(Field).SetValue(Data, TValue.From(TGuid.Create(Arg)));
end;

并相应地标记该字段：

[JsonReflect(ctString, rtString, TGuidInterceptor)]
FID: TGUID;

Answer 2

没有为TGUID 类型的字段生成 RTTI。

因此，为了序列化您的类，您可以只使用设置字符串属性的 getter/setter 函数。

类似：

TMyPacket = class(TObject)
  Private
    FIDValue: TGUID;
    FToIP: string;
    FToPort: integer;
    FSent: boolean;
    FSentAt: TDateTime;
    FAck: boolean;
    FTimeOut: Cardinal;
    FDataToSendSize: UINT64;
    FDataToSend: AnsiString;
    procedure SetID(const value: string);
    function GetID: string;
  public
    constructor create;
    destructor free;
    property IDValue: TGUID read FID write FID;
  published
    property ID: string read GetID write SetID;
    property ToIP: string read FToIP write FToIP;
    property ToPort: integer read FToPort write FToPort
  ...

procedure TMyPacket.SetID(const value: string);
begin
  fIDValue := StringToGUID(value);
end;

function TMyPacket.GetID: string;
begin
  result := GUIDToString(fIDValue);
end;

然后序列化应该可以工作，使用"ID": 字符串字段，您将在IVValue 公共属性中获得TGUID 值。