FreePascal x64 上对系统单元函数的汇编调用

Question

我有一些 Delphi/汇编代码，可以为 Win32、Win64 和 OSX 32 编译和工作正常 (XE2)。但是，由于我需要它在 Linux 上工作，我一直在研究编译它的 FPC 版本（所以远，Win32/64，Linux32/64）。

总的来说，它运行良好，但我无法开始工作的一件事是调用/跳转到 Delphi System 单元函数，如下所示：

  jmp System.@FillChar

这似乎在 FPC Win32/Linux32 上具有预期的效果，但失败除了在 FPC Win64/Linux64 上的异常。 （我对平台之间的调用约定差异非常熟悉，所以不要认为这是原因。）

在适用于 x64 平台的 FPC 上执行此操作的正确方法是什么？

[Edit1] --- 作为对 David 的评论的回应，这里有一个简化的程序来说明问题（至少我希望它是准确的）：

program fpcx64example;
{$IFDEF FPC}
  {$MODE DELPHI}
  {$ASMMODE INTEL}
{$ELSE}
  {$APPTYPE CONSOLE}
{$ENDIF}

procedure FillMemCall (p: pointer; len: longword; val: byte);
asm
  // this function and the System function have the same parameters
  // in the same order -- they are already in their proper places here
  jmp System.@FillChar
end;

function MakeString (c: AnsiChar; len: longword): AnsiString;
begin
  Setlength (Result, len);
  if len > 0 then FillMemCall (PAnsiChar(Result), len, byte(c));
end;

begin
  try
    writeln (MakeString ('x',10));
  except
    writeln ('Exception!');
  end;
end.

使用 FPC 编译： [Win32:] fpc.exe fpcx64example.dpr, [Win64:] ppcrossx64.exe fpcx64example.dpr, [Linux32:] fpc.exe -Tlinux -XPi386-linux- -FD[path]\FPC\bin\i386-linux fpcx64example.dpr, [Linux64 :]ppcrossx64.exe -Tlinux -XPx86_64-linux- -FD[FPCpath]\bin\x86_64-linux fpcx64example.dpr.

适用于 Delphi (Win32/64)。对于 FPC，删除上面的 jmp System.@FillChar 可以消除 x64 上的异常。

解决方案（感谢 FPK）：

Delphi 和 FPC 在完全相同的条件下不会为函数生成堆栈帧，因此RSP 寄存器在两者编译的版本中可能会有不同的对齐方式。解决方案是避免这种差异。对于上面的 FillMemCall 示例，这样做的一种方法如下所示：

{$IFDEF CPU64} {$DEFINE CPUX64} {$ENDIF} // for Delphi compatibility
procedure FillMemCall (p: pointer; len: longword; val: byte);
  {$IFDEF FPC} nostackframe; {$ENDIF} //Force same FPC behaviour as in Delphi
asm
  {$IFDEF CPUX64}
    {$IFNDEF FPC} .NOFRAME {$ENDIF} // To make it explicit (Delphi)...
    // RSP = ###0h at the site of the last CALL instruction, so
    // since the return address (QWORD) was pushed onto the stack by CALL,
    // it must now be ###8h -- if nobody touched RSP.
    movdqa xmm0, dqword ptr [rsp + 8] // <- Testing RSP misalignment -- this will crash if not aligned to DQWORD boundary
  {$ENDIF}
  jmp System.@FillChar
end;

这不是很漂亮，但它现在适用于 Win/Linux 32/64 的 Delphi 和 FPC。

Answer 1

简短回答：正确的方法是使用调用指令。

长答案：x86-64 代码要求堆栈是 16 字节对齐的，因此 FillMemCall 在入口点包含一个编译器生成的 sub rsp,8 和一个 add rsp,8 在出口处（添加其他 8 个字节/由 call/ret 对删除）。另一方面，Fillchar 是手动编码的汇编程序，并使用 nostackframe 指令，因此它不包含编译器生成的子/添加对，并且一旦留下填充字符，堆栈就会混乱，因为 FillChar 之前不包含 add rsp,8 ret 指令。

解决方法，例如对 FillMemCall 使用 nostackframe 指令或在执行 jmp 之前调整堆栈可能是可能的，但可能会因将来的编译器更改而中断。

Answer 2

在这种情况下，最简单的方法是去掉汇编程序，只使用帕斯卡代码：

procedure FillMemCall (p: pointer; len: longword; val: byte); inline; 
begin
  fillchar(p^,len,val);
end;

它适用于 FPC 和 Delphi（对于已知 inline 的较新版本）。

它适用于所有平台和 CPU（甚至 arm）。

而且会比asm jmp @System.FillChar end快，因为过程被声明为inline：不会生成代码，调用FillMemCall会直接调用fillchar，即会生成如下代码：

function MakeString (c: AnsiChar; len: longword): AnsiString;
begin
  Setlength (Result, len);
  if len > 0 then 
    fillchar(pointer(Result)^, len, c);
end;