使用 clojure 格式化答案

【问题标题】：Formatting using clojure使用 clojure 格式化
【发布时间】：2015-12-08 19:42:06
【问题描述】：

上下文

我有一个列表和一个集合，其中包含两种不同格式的相似数据。

("XXX_1_10/22/2015" "YYY_1.5_11/22/2015" "XX_2.5_10/23/2015" "YY_5_11/26/2015")

#{"XXX 1.000 OCT15" "XX 2.500 OCT2015" "ZZZ 3.500 JAN2016"}

我需要使用这两种数据结构之间的通用列表 clojure。

应该是：

("XXX 1.000 OCT15" "XX 2.500 OCT2015")

问题

有人可以帮我解决这个问题吗？

【问题讨论】：

您的第二种数据格式{...} 是地图。当然应该是#{} - set.
我无法更改数据结构中的格式。我已经测试了使用 (keep #set list) 比较它们的方法，它返回公共值。但是格式化日期以使它们相似是我面临的问题。
随意添加该代码。它使愿意回答的人更容易在此基础上进行构建

标签： list clojure formatting set comparison

【解决方案1】：

您必须首先标准化所有值。使用正则表达式。

(def months ["JAN" "FEB" "MAR" "APR" 
             "MAY" "JUN" "JUL" "AUG" 
             "SEP" "OCT" "NOV" "DEC"])

(defn normalize-underscored [value]
  (let [[_ text val month year]
        (re-matches #"(.+?)_([\d.]+)_(\d+)/\d+/(\d{4})" value)]
    [text
     (Float/parseFloat val)
     (months (dec (Long/parseLong month)))
     year]))

(defn normalize-spaced [value]
  (let [[_ text val month year]
        (re-matches #"(.+?)\s([\d.]+)\s(\w{3})(\d{2,4})" value)]
    [text (Float/parseFloat val) month
     (if (== 2 (count year)) (str "20" year) year)]))

这就是它的标准化方式：

user> (normalize-underscored "XX_2.5_10/23/2015")
["XX" 2.5 "OCT" "2015"]
user> (normalize-spaced "XXX 1.000 OCT15")
["XXX" 1.0 "OCT" "2015"]
user> (normalize-spaced "ZZZ 3.500 JAN2016")
["ZZZ" 3.5 "JAN" "2016"]

然后只比较标准化版本：

(def underscored '("XXX_1_10/22/2015" "YYY_1.5_11/22/2015"
                   "XX_2.5_10/23/2015" "YY_5_11/26/2015"))

(def spaced #{"XXX 1.000 OCT15" "XX 2.500 OCT2015" 
              "ZZZ 3.500 JAN2016"})

(for [uv (map normalize-underscored underscored)
      s spaced
      :when (= uv (normalize-spaced s))]
  s)

输出：

("XXX 1.000 OCT15" "XX 2.500 OCT2015")

或者更好地将结果重新格式化为更一致的形式，如下所示：

(map (partial apply format "%s %.3f %s%s")
     (keep (set (map normalize-spaced spaced))
           (map normalize-underscored underscored)))

输出：

("XXX 1.000 OCT2015" "XX 2.500 OCT2015")

【讨论】：