立即学习 Prolog！ DCG 实践示例

Question

我一直在自学通过Learn Prolog Now!，现在正在学习定从句语法。我在实践会议的一项任务中遇到了一些困难。 The task 阅读：

形式语言aⁿb^2mc^2mdⁿ由以下形式的所有字符串组成: 一个完整的 as 块，后面是一个完整的 bs 块，然后是一个完整的 cs 块，然后是一个完整的 bs 块ds，使得 a 和 d 块的长度完全相同，而 c 和 d 块的长度也完全相同，并且分别由偶数个 c 和 d 组成。比如ε、abbccd、aaabbbbccccddd都属于aⁿb^2mc^2mdⁿ。编写一个生成这种语言的 DCG。

我能够编写生成 aⁿdⁿ、b^2mc^2m 和甚至 aⁿb^2m 和 c^2mdⁿ... 但我似乎无法加入所有将这些规则转化为 aⁿb^2mc^2mdⁿ。以下是我可以生成aⁿdⁿ和b^2mc^2m的规则。

s1 --> [].
s1 --> a,s1,d.
a --> [a].
d --> [d].

s2 --> [].
s2 --> c,c,s2,d,d.
c --> [c].
d --> [d].

aⁿb^2mc^2mdⁿ真的是CFG吗，能写吗仅使用课程中所教内容的 DCG（没有额外的参数或代码等）？如果是这样，任何人都可以为我提供一些指导，我可以如何加入这些，以便我可以解决给定的任务？

Answer 1

@Timothy，您的答案有效，但会产生重复：

?- length(S,_), s(S,[]).
S = [] ;
S = [a, d] ;
S = [a, d] ;            % XXX
S = [b, b, c, c] ;
S = [a, a, d, d] ;
S = [a, a, d, d] ;      % XXX

这可以通过删除一个子句来解决，留下 DCG：

s --> x.
s --> a,s,d.

x --> [].
x --> b,b,x,c,c.

% a, b, c, d the same

这会生成：

?- length(S,_), s(S,[]).
S = [] ;
S = [a, d] ;
S = [b, b, c, c] ;
S = [a, a, d, d] ;
S = [a, b, b, c, c, d] ;
S = [a, a, a, d, d, d] ;
S = [b, b, b, b, c, c, c, c] ;
S = [a, a, b, b, c, c, d, d] ;
S = [a, a, a, a, d, d, d, d] ;

Answer 2

我相信我想通了......

s --> x.
s --> a,d.
s --> a,s,d.

x --> [].
x --> b,b,x,c,c.

a --> [a].
b --> [b].
c --> [c].
d --> [d].

?- s([],[]).
Yes

?- s([a,b,c,c,d],[]).
No

?- s([a,a,a,b,b,c,c,d,d,d],[]).
Yes

看着解决方案并想，“我绞尽脑汁想那个是很有趣的？”但我想这只是学习新东西的一半乐趣，尤其是当它像来自命令式编程背景的逻辑编程时。

Answer 3

怎么样：

n(L,N) --> n(L,N,0).

n(_,N,N) --> [], !.
n(L,N,K) --> L, {K1 is K + 1}, n(L, N, K1).

abbccd(N,M) -->
    {M1 is 2*M},
    n("a",N),
    n("b",M1),
    n("c",M1),
    n("d",N).

gen :-
    forall((
           between(1,4,N),
        between(1,4,M),
        phrase(abbccd(N,M),S),
        string_to_atom(S,A)
           ),
           writeln(A)).

执行：

 ?- gen.
abbccd
abbbbccccd
abbbbbbccccccd
abbbbbbbbccccccccd
aabbccdd
aabbbbccccdd
aabbbbbbccccccdd
aabbbbbbbbccccccccdd
aaabbccddd
aaabbbbccccddd
aaabbbbbbccccccddd
aaabbbbbbbbccccccccddd
aaaabbccdddd
aaaabbbbccccdddd
aaaabbbbbbccccccdddd
aaaabbbbbbbbccccccccdddd
true.