Perl 中的智能正则表达式？

Question

背景

---

考虑以下输入：

<Foo
    Bar="bar"
    Baz="1"
    Bax="bax"
>

处理后，我需要它如下所示：

<Foo
    Bar="bar"
    Baz="1"
    Bax="bax"
    CustomAttribute="TRUE"
>

实施

---

这是所有我需要为不超过 5 个文件做的事情，所以使用正则表达式以外的任何东西似乎都过大了。无论如何，我想出了以下（Perl）正则表达式来完成这个：

$data =~ s/(<\s*Foo)(.*?)>/$1$2 CustomAttribute="TRUE">/sig;

问题

---

这很好用，但是有一个明显的问题。这种模式是“愚蠢的”，因为如果 CustomAttribute 已经被添加，上面概述的操作只会盲目地追加另一个 CustomAttribute=...。

当然，一个简单的解决方案是编写一个辅助表达式，在运行替换操作之前尝试匹配CustomAttribute。

问题

---

由于我对脚本语言和正则表达式领域相当陌生，我想知道是否可以在不引入任何宿主语言结构（即 Perl 中的 if 语句）的情况下解决这个问题，并且只需使用比我上面写的更“智能”的版本？

Answer 1

我不会在你不应该为此使用正则表达式的问题上打败你。我的意思是，您不应该，但您显然从您在问题中所说的内容中知道这一点，所以继续……

可以完成您所要求的事情称为negative lookahead assertion（通常是(?!...)），它基本上表示如果在此之前找到断言中的模式，您不希望匹配应用观点。在您的示例中，如果 CustomAttribute 已经存在，您不希望它应用，所以：

$data =~ s/(<\s*Foo)(?![^>]*\bCustomAttribute=)(.*?)>/$1$2CustomAttribute="TRUE">/sig;

Answer 2

这听起来像是XML::Twig 的工作，它可以处理 XML 并在遇到 XML 时更改其中的部分内容，包括向标签添加属性。我怀疑您会花费尽可能多的时间来习惯 Twig，并且您会找到一个仅在大多数情况下有效的正则表达式解决方案。而且，最后你会知道足够多的 Twig 在下一个项目中使用它。 :)

Answer 3

我想是时候讲课了；--)

我不确定您为什么认为使用成熟的 XML 处理器是多余的。使用适当的工具编写代码实际上更容易。正则表达式将更加复杂，并且将依赖于对数据的不成文假设，这是危险的。其中一些假设可能是：属性值中没有“>”，没有 CDATA 部分，标签或属性名称中没有非 ascii 字符，一致的属性值引用......

正则表达式唯一能给您的是保证输出保持数据的原始格式（在您的情况下，属性每个都在单独的行上）。但是如果你的格式是一致的，那是可以做到的，如果不是，那也没关系，除非你把你的 XML 保存在一个面向行的版本控制系统中。

这是一个使用 XML::Twig 的示例。它假定您有足够的内存来将任何整个 Foo 元素保存在内存中，并且它甚至可以在 DATA 部分中公认的 XML 部分上工作。使用 XML::LibXML 可能同样容易（读取内存中的 XML，选择所有 Foo 元素，为每个元素添加属性，输出，据我计算，这是 5 行易于理解的行）。

#!/usr/bin/perl

use strict;
use warnings;

use XML::Twig;

my( $tag, $att, $val)= ( 'Foo', 'CustomAttribute', 'TRUE');

XML::Twig->new(                 # only process those elements
                twig_roots => { $tag => sub { 
                                              # add/set attribute
                                              $_->set_att( $att => $val); 
                                              # output and free memory
                                              $_->flush;
                                            }
                              },
                twig_print_outside_roots => 1, # output everything else
                pretty_print => 'cvs',         # seems to be the right format
              )
         ->parse( \*DATA)  # use parsefile( $file) if parsing... a file
         ->flush;          # not needed in XML::Twig 3.33
__DATA__
<doc>
  <Foo
      Bar="bar"
      Baz="1"
      Bax="bax"
  >
  here is some text
  </Foo>
  <Foo CustomAttribute="TRUE"><Foo no_att="1"/></Foo>
  <bar><![CDATA[<Foo no_att="1">tricked?</Foo>]]></bar>
  <Foo><![CDATA[<Foo no_att="1" CustomAttribute="TRUE">tricked?</Foo>]]></Foo>
  <Foo
      Bar=">"
      Baz="1"
      Bax="bax"
  ></Foo>
  <Foo
      Bar="
>"
      Baz="1"
      Bax="bax"
  ></Foo>
  <Foo
      Bar=">"
      Baz="1"
      Bax="bax"
      CustomAttribute="TRUE"
  ></Foo>
  <Foo
      Bar="
>"
      Baz="1"
      Bax="b
ax"
      CustomAttribute="TR
UE"
  ></Foo>
</doc>

Answer 4

您可以通过带有“e”修饰符的函数发送匹配项以进行更多处理。

my $str = qq`
<Foo
    Bar="bar"
    Baz="1"
    Bax="bax"
    CustomAttribute="TRUE"
>
<Foo
    Bar="bar"
    Baz="1"
    Bax="bax"
>
`;

sub foo {
    my $guts = shift;
    $guts .= qq` CustomAttribute="TRUE"` if $guts !~ m/CustomAttribute/;
    return $guts;
}
$str =~ s/(<Foo )([^>]*)(>)/$1.foo($2).$3/xsge;