填充和列出一对多哈希数据结构

Question

下面的脚本列出了解析配置文件中的所有作业，并仅取出 运行作业的可执行文件 - perl 或 shell 脚本。然后它打开 可执行文件，并逐行遍历它并取出它读取的文件路径 in 及其输出的路径。

#!/usr/bin/perl
use strict;
use warnings;
open my $fh_rmancfg, '<', "/data/autosys-us.cfg"
    or die "can't open file $!" ;
while ( my $cfg_line = <$fh_rmancfg>) {
    if ($cfg_line =~ /executable/) {
        my $cut_cfg_line = substr "$cfg_line", 13 ;
        if ($cut_cfg_line =~ /(\/\S*\.(sh|pl|ksh))/) {
            chomp($cut_cfg_line);
            open my $fh_cut_cfg, '<', $cut_cfg_line
                or warn qq{Can't open file "$cut_cfg_line" : $! } ;
            while (my $path = <$fh_cut_cfg>) {
                if ($path =~ /(\"\/\S*)\"/) {
                    print "$cut_cfg_line --->  $path";
                }
            }
        }
    }
}

这很好用，除非我将这些值泵入哈希 键被覆盖 - 请注意，有时一个键有一个值， 有时一个键有零个或多个值。

program_1  -->  filepath_one
program_1  -->  filepath_two
program_1  -->  filepath_three
program_2  -->  filepath_one
program_2  -->  filepath_two
program_2  -->  filepath_three
program_2  -->  filepath_four
program_3  -->  filepath_one
program_4  -->  filepath_one
program_4  -->  filepath_one
program_4  -->  filepath_two
program_5  -->  filepath_one
program_5  -->  filepath_two
program_5  -->  filepath_thee
program_5  -->  filepath_four
program_5  -->  filepath_five
program_5  -->  filepath_six
program_5  -->  filepath_seven
program_5  -->  filepath_eight

我需要一个可以输入唯一键的数据结构 但有很多价值。我想弄清楚这是什么 结构是以及如何将值放入结构中。

program_1  -->  filepath_one
           -->  filepath_two
           -->  filepath_three
program_2  -->  filepath_one
           -->  filepath_two
           -->  filepath_three
           -->  filepath_four
program_3  -->  filepath_one
program_4  -->  filepath_one
           -->  filepath_one
           -->  filepath_two
program_5  -->  filepath_one
           -->  filepath_two
           -->  filepath_thee
           -->  filepath_four
           -->  filepath_five
           -->  filepath_six
           -->  filepath_seven
           -->  filepath_eight

Answer 1

正如您所发现的，当您执行以下操作时：

$hash{key} = "value";
$hash{key} = "new value";

原来的值没了。幸运的是，Perl 5 允许您使用references。 Perl 引用允许您执行诸如将哈希键指向值数组而不是单个值的操作。

$hash{key} = [];   # The value is a reference to an array
$hash{key}->[0] = "value";
$hash{key}->[1] = "new value";

现在，$hash{key} 包含两个值！该数组称为引用，有时甚至称为匿名数组，因为数组本身没有与之关联的变量名。

您可以通过在变量前面添加反斜杠来创建引用：

$array_reference = \@array;

要取消引用（即把引用变回数组），你把正确的sigil放在它前面：

我的@new_array = @{ $array_reference };

使用引用允许 Perl 使用更复杂的数据结构。您可以使用push 将值推送到特定哈希值指向的数组引用，而不是简单地为哈希分配一个值：

my %hash;
$hash{key} = [];          # This key is an array reference
for each $value ( qw(value1 value2 value3 ) ) {
    push @{ $hash{key} }, $value;
}

阅读Perl Tutorial on References，它应该让您了解如何使用数组散列来存储所有值。

Answer 2

如果您要使用重复的键，请使用需要使用数组的散列。您可以在Perl Data Structures Cookbook中阅读更多关于不同数据结构的信息

这是一个简单的例子：

#!/usr/bin/perl
use strict;
use warnings;

my %hashofArrays;

while (<DATA>) {
    my ( $key, $value ) = split;
    push @{ $hashofArrays{ $key } }, $value;
}

use Data::Dumper;

print Dumper \%hashofArrays;

__DATA__
program_1 filepath_one
program_1 filepath_two
program_1 filepath_three
program_2 filepath_one
program_2 filepath_two
program_2 filepath_three
program_2 filepath_four
program_3 filepath_one
program_4 filepath_one
program_4 filepath_one
program_4 filepath_two
program_5 filepath_one
program_5 filepath_two
program_5 filepath_thee
program_5 filepath_four
program_5 filepath_five
program_5 filepath_six
program_5 filepath_seven
program_5 filepath_eight

输出：

$VAR1 = {
          'program_5' => [
                           'filepath_one',
                           'filepath_two',
                           'filepath_thee',
                           'filepath_four',
                           'filepath_five',
                           'filepath_six',
                           'filepath_seven',
                           'filepath_eight'
                         ],
          'program_3' => [
                           'filepath_one'
                         ],
          'program_2' => [
                           'filepath_one',
                           'filepath_two',
                           'filepath_three',
                           'filepath_four'
                         ],
          'program_1' => [
                           'filepath_one',
                           'filepath_two',
                           'filepath_three'
                         ],
          'program_4' => [
                           'filepath_one',
                           'filepath_one',
                           'filepath_two'
                         ]
        };