Haskell - 合并排序，对单词和数字进行排序

Question

我在 Haskell 中编写了一个合并排序，它在使用数字时有效，但不适用于单词，我认为它会。使用单词和字母时，我只会得到“不在范围内”。我做错了什么？

这是我的代码：

merge :: Ord a => [a] -> [a] -> [a]
merge [] ys = ys
merge xs [] = xs
merge (x:xs) (y:ys)
    | x <= y = x : merge xs (y:ys)
    | otherwise = y : merge (x:xs) ys

mergeSort :: Ord a => [a] -> [a]
mergeSort [] = []
mergeSort [x] = [x]
mergeSort xs
    = merge (mergeSort top) (mergeSort bottom)
    where
    (top, bottom) = splitAt (length xs `div` 2) xs

Answer 1

你是这样输入的吗？

[this,is,an,example,sentence]

语法不正确。如果你想输入一个文字字符串，你必须把它用双引号括起来（"）：

["this","is","an","example","sentence"]

如果这不是您的错误，请随意忽略此答案。

Answer 2

您的代码运行良好。

但是我建议一次性拆分列表，而不使用length。当然，顺序在这里并不重要，只是我们有两个大小大致相同的列表。你可以这样做：

splitList [] = ([],[])
splitList [x] = ([x],[])
splitList (x:y:zs) = let (xs,ys) = splitList zs in (x:xs, y:ys)  

...或尾递归...

splitList zs = go zs [] [] where
   go [] xs ys = (xs, ys)
   go [x] xs ys = (x:xs, ys)
   go (x:y:zs) xs ys = go zs (x:xs) (y:ys)    

...或使用索引...

splitList xs = (go even, go odd) where
   go f = map snd $ filter (f.fst) $ indexed
   indexed = zip [0..] xs

...或使用折叠...

import Data.List

splitList zs = snd $ foldl' go (True,([],[])) zs where
   go (True,(xs,ys)) x = (False,(x:xs,ys))   
   go (False,(xs,ys)) x = (True,(xs,x:ys))