【问题标题】：Extract time slot based on interval value根据区间值提取时隙
【发布时间】：2021-05-22 05:12:34
【问题描述】：

在单元格 A1 中，我有一个间隔值，它是一个整数，可以是 1、5 或 15，表示 1 分钟、5 分钟或 15 分钟

在“B1:B12”范围内，我有样本数据（会更多）

现在在 C 列中，我需要根据单元格 A1 中可用的数字提取时隙。

如果单元格 A1 有 15，那么列 C 将包含以下内容

12:15
12:30

因为列中的前 15 分钟从 12:15 开始，然后将其递增 15 分钟，直到最后一个可用数据落在该 15 分钟范围内。

如果单元格 A1 有 5，那么列 C 将包含以下内容

因为前 5 分钟从 12:05 开始，然后将其递增 5 分钟，直到最后一个可用数据落在该 15 分钟范围内。

如果单元格 A1 有 1，则提取 除重复项之外的所有内容。

我希望我已经正确地解释了这个场景。我想不出在 excel vba 中执行此操作的逻辑，需要有关如何开始的帮助，以便我可以尝试应用该逻辑并提出代码。

谢谢

编辑

我正在添加所需结果的图片。如果 A1 包含 1，则复制 C 列中的所有时间戳，不包含重复项

如果 A1 包含 5 则仅显示 5 次 5 分钟间隔

如果 A1 包含 15 则仅显示 3 次 15 分钟间隔

【问题讨论】：

必须是VBA吗？我认为这是一个相当简单的公式。
恐怕这个问题并没有你想的那么清楚……你说的是“1、5或15”。 '12:03', '12:06' 之类的 A1 值，不包括在第一个提到的范围内，它们会被忽略吗？那么，代码是否应该在 B:B 中的所有值之间进行迭代，以及如何在 C:C 中返回？你到底是怎么给我们看的？我的意思是一个在另一个之上的值？ B:B 范围有什么格式？ C:C 的格式是什么？ “单元格 A1 有 1 然后提取除重复项之外的所有内容”是什么意思？这个提取是什么意思？你想引用 B 吗？
我建议您编辑您的问题并放置两张图片。一个是现有情况，第二个是处理后的情况......
@FaneDuru 不，它们不应被忽略，是的代码在 B 中的所有值之间迭代并在 C 中返回。范围没有任何公式，C 中的格式将是时间格式。简而言之，我希望将所有时间戳分组为 1 分钟、5 分钟和 15 分钟。我将使用所需输出的图片编辑我的问题
现在我正在查看您的图片，并且可以得出结论，这个世界上的任何人都无法理解您在编辑之前表达的问题。这是一个如此简单的任务，但没有清楚地描述......

标签： excel vba unique excel-2007 array-formulas

【解决方案1】：

使用VBA（一）返回数组

您需要ctrl-shif-enter

Option Explicit

Function get_unique_time_interval(ByVal interval_size As Double, ByVal input_data As Range) As Variant

  interval_size = interval_size / 60# / 24#
  
  Dim d
  Set d = CreateObject("Scripting.Dictionary")
  
  Dim r As Range
  For Each r In input_data
    Dim t As Double
    t = Int(r.Value / interval_size) * interval_size
    If Not d.exists(t) Then d.Add t, t
  Next r
  
  get_unique_time_interval = Application.WorksheetFunction.Transpose(d.keys)

End Function

(2) 硬编码输出到C1

option explicit
Sub get_unique_time_interval_sub()

  Dim interval_size As Double: interval_size = ActiveSheet.Range("a1").Value
  Dim input_data As Range: Set input_data = Range(ThisWorkbook.Sheets(1).Range("b1"), ThisWorkbook.Sheets(1).Range("b1").End(xlDown))
  
  interval_size = interval_size / 60# / 24#
  
  Dim d
  Set d = CreateObject("Scripting.Dictionary")
  
  Dim r As Range
  For Each r In input_data
    Dim t As Double
    t = Int(r.Value / interval_size) * interval_size
    If Not d.exists(t) Then d.Add t, t
  Next r
  
  Dim v As Variant
  Dim i As Long
  i = 0
  If Not IsEmpty(Range("c1").Value) Then Range(Range("c1"), Range("c1").End(xlDown)).ClearContents
  For Each v In d.keys
    ThisWorkbook.Sheets(1).Range("c1").Offset(i, 0).Value = v
    i = i + 1
  Next v

End Sub

【讨论】：

【解决方案2】：

这在C1 中用作单个单元格公式：

=UNIQUE(INT(B1:B12/(A1/60/24))*(A1/60/24))

分解：

A1/60/24

是您想要的时间间隔（A1 以分钟为单位，因此除以每小时 60 分钟和每天 24 小时即可得到 Excel 时间间隔单位）。那么：

INT(B1:B12/(A1/60/24))

将您向下舍入到时间段的开始。那么：

*(A1/60/24)

将您转换回输入时间所在的时间间隔。那么：

UNIQUE(

提取唯一值。

这里有帮助的是，通过将B1:B12 包含在一个范围内，它会使所有内容（有帮助）溢出

【讨论】：

感谢您的回复...我试图将公式放入 C1 但它显示#NAME？对我来说
猜猜这可能是一个错字 - 你能截屏单元格内容吗？你用的是什么版本的excel，什么语言？
我使用的是 excel 2007。我在你的回答下添加了截图
啊好吧 - 功能在 2007 年不可用 - answers.microsoft.com/en-us/msoffice/forum/… - 你有什么理由不想将其作为 VBA 宏执行吗？
我可以使用基于宏或公式的解决方案......任何能给我结果的东西。感谢您的帮助，公式看起来很棒...我真的希望在另一台具有最新 Excel 的计算机上检查一下。我明天去看看

【解决方案3】：

如果您接受基于公式的答案，那么这应该适合您：

A1：某个区间值。

B1：

=0.5+A1/(24*60)

其中 0.5 在 Excel 中表示 12:00。

在 B2 中：

=B1+$A$1/(24*60)

然后把这个公式拖到你需要的地方。

例子：

【讨论】：

谢谢...使用公式似乎是一个很好的逻辑，但它并没有给出我想要的结果。让我张贴一张图片，说明所需的输出是什么样的。
我发布了这张照片。如果您可以查看它并让我知道是否有办法在基于公式的解决方案中实现这一点，我们将不胜感激。 B 列数据为原始数据。我不需要那里的公式...我需要 C 列中的输出