文本中的 VBA 选择案例循环

Question

尝试遍历一系列单元格并根据另一个单元格中的文本值为它们分配标签。所以如果 Cell J2 = "This Text" Then Cell A2 = "This Label"

截至目前，我不断收到运行时错误编号 424，说明需要对象

Private Function getPhase(ByVal cell As Range) As String
Select Case cell.Text
    Case "Text1"
        getPhase = "Label1"
    Case "Text2"
        getPhase = "Label2"
End Select
End Function


Sub setPhase()
Dim cycle As Range
Dim phase As Range


Set cycle = Range("J2:J10")
Set phase = Range("A2:A10")

For Each cell In phase.Cells
    phase.Text = getPhase(cycle)
Next cell

End Sub

Answer 1

你已经得到了答案 :) 让我在我的帖子中做一些解释 :)

你不能用这个。

phase.Text = getPhase(cycle)

.Text 是 只读 属性。即您不能写入它，而只能从中读取。你必须使用.Value

其次，如果您从同一行中选取值，则无需定义第二个范围。您可以随时使用.Offset 属性。看到这个

Option Explicit

Sub setPhase()
    Dim rng As Range, phase As Range

    Set phase = Sheets("Sheet1").Range("A2:A10")

    For Each rng In phase
        rng.Value = getPhase(rng.Offset(, 9))
    Next
End Sub

Function getPhase(ByVal cl As Range) As String
    Select Case cl.Value
        Case "Text1"
            getPhase = "Label1"
        Case "Text2"
            getPhase = "Label2"
    End Select
End Function

Select Case cell.Text 也没有任何问题，因为您只是在阅读它。但是，使用.Value 总是好的。原因是 .Value 属性返回单元格的实际值，而 .Text 属性返回显示在屏幕上的文本。在更高版本的 Excel 中，文本的限制约为 8k 个字符。另一方面，.Value 最多可以存储 32k 个字符。

Answer 2

我改变了循环。这假设两个范围的长度相同

Function getPhase(ByVal cell As Range) As String

   Select Case cell.Value
    Case "Text1"
        getPhase = "Label1"
    Case "Text2"
        getPhase = "Label2"
  End Select


End Function


Sub setPhase()
Dim cycle As Range
Dim phase As Range


Set cycle = ThisWorkbook.Sheets("myexample").Range("J2:J10")
Set phase = ThisWorkbook.Sheets("myexample").Range("A2:A10")

Dim i As Integer
For i = 1 To phase.Cells.Count
    phase.Cells(i).Value = getPhase(cycle.Cells(i))
Next i

End Sub

...或者正如 siddharth 建议的那样，使用公式。

或者通过VBA做公式：

Sub setPhase()

Dim phase As Range
Set phase = Excel.ThisWorkbook.Sheets("Sheet1").Range("A2:A10")
phase.Value = "=IF(J2=""Text1"",""Label1"",IF(J2=""Text2"",""Label2"",""""))"

End Sub

Answer 3

这是我的版本：

Private Function getPhase(ByVal cell As Range) As String
    Select Case cell.Text
        Case "Text1"
            getPhase = "Label1"
        Case "Text2"
            getPhase = "Label2"
    End Select
End Function


Sub setPhase()
    Dim cycle As Range
    Dim phase As Range


    Set cycle = ActiveSheet.Range("b2:b10")
    Set phase = ActiveSheet.Range("A2:A10")

    For Each cell In phase.Cells
        cell.Value = getPhase(cycle.Cells(cell.Row, 1))
    Next cell

End Sub