我应该使用哪个事件来显示绘图？

Question

我需要将一些图形放在 TableLayoutPanel 的一个部分中。

我通过在 TLP 的一个单元格中创建一个 PictureBox 来做到这一点。

不能让两件事起作用：

1) 初始显示为空白！绘图仅在您调整表单大小时出现

2) 与收缩相比，扩展大小时，resize 事件不会同样触发。

任何改善上述两个问题的建议都会很棒！

这是我的代码。表单中有一个 2x2 TableLayoutPanel，TLP 的一个单元格中有一个 PictureBox。 TLP 和 PictureBox 都设置为 Fill Parent：

Imports System.Drawing.Drawing2D

Public Class Form1
    Private g As Graphics
    Dim n As Integer = 0

Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Debug.Print(String.Format("{0}{0}Form1_Load at {1}", vbCrLf, Now()))
    Me.SetDesktopLocation(800, 200)
End Sub

Private Sub Form1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles MyBase.Paint
    n += 1
    Debug.Print(String.Format("MyBase.Paint: {0}", n))
    DisplayMyStuff()
End Sub

Private Sub PictureBox1_Resize(sender As Object, e As EventArgs) Handles Pict    ureBox1.Resize
    n += 1
    Debug.Print(String.Format("PictureBox1.Resize: {0}  PictureBoxSize = {1} / {2}", n, PictureBox1.Width, PictureBox1.Height))
    If g IsNot Nothing Then
        g.Dispose()
    End If
    g = PictureBox1.CreateGraphics()
End Sub

Private Sub DisplayMyStuff()
    Dim rect1 As Rectangle
    Dim rect2 As Rectangle
    Dim pt1 As New Point(50, 50)
    Dim pt2 As New Point(100, 100)
    Dim pt3 As New Point(150, 150)
    Dim brR As New SolidBrush(Color.Red)
    Dim linGradBr As New LinearGradientBrush(pt2, pt3, Color.Yellow, Color.Blue)
    Dim pictBoxSize As Size
    Dim sz As Size
    Dim width, height As Integer

    pictBoxSize = New Size(CType(PictureBox1.Size, Point))
    width = CInt(pictBoxSize.Width / 2)
    height = CInt(pictBoxSize.Height / 2)
    sz = New Size(width, height)
    n += 1
    Debug.Print(String.Format("DisplayMyStuff: {0}, Half-Size = {1} / {2}", n, width, height))
    g.Clear(Color.Bisque)
    rect1 = New Rectangle(pt1, sz)
    rect2 = New Rectangle(pt2, sz)
    g.FillRectangle(brR, rect1)
    g.FillRectangle(linGradBr, rect2)
    brR.Dispose()
    linGradBr.Dispose()
End Sub

结束类

Answer 1

显然，您正在尝试绘制到图片框 (g = PictureBox1.CreateGraphics())

东西消失的原因是当大小改变时，或者有东西经过窗口时，控件和窗体需要重新绘制。这发生在 Paint 事件中，因此您的代码需要在那里进行绘图。与 PictureBox 图像不同，绘制到窗体或控件的项目本身不是持久的，这是通过在 Paint 事件中绘制来完成的。

这实质上是您的 DrawMyStuff 过程重新定位到 Picbox 的 Paint 事件。

Private Sub PictureBox1_Paint(sender As Object, 
          e As PaintEventArgs) Handles PictureBox1.Paint
    Dim pt1 As New Point(50, 50)
    Dim pt2 As New Point(100, 100)
    Dim pt3 As New Point(150, 150)

    Dim sz As New Size(CInt(PictureBox1.Size.Width / 2),
                       CInt(PictureBox1.Size.Height / 2))
    n += 1
    Debug.Print(String.Format("DisplayMyStuff: {0}, 
            Half-Size = {1} / {2}", n, sz.Width, sz.Height))

    Dim rect1 As New Rectangle(New Point(50, 50), sz)
    Dim rect2 As New Rectangle(New Point(100, 100), sz)

    Using linGradBr As New LinearGradientBrush(pt2, pt3, Color.Yellow, Color.Blue)

        e.Graphics.Clear(Color.Bisque)

        e.Graphics.DrawRectangle(Pens.Black, rect1)
        e.Graphics.DrawRectangle(Pens.Black, rect2)

        e.Graphics.FillRectangle(Brushes.Red, rect1)
        e.Graphics.FillRectangle(linGradBr, rect2)

    End Using
End Sub

如果您实际上是在尝试在表单上绘画，那么 Grim 的答案就是解决方案。在那里您响应 Form Paint 事件。无论哪种情况，都使用 Windows 提供的 Graphics 对象作为 EventArg。

上面，您使用的是 PictureBox 的 Graphics 对象（通过事件参数），因此输出到 PictureBox。

---

Windows 不会知道您在 Paint 事件中绘制了什么东西，因此您需要告诉它图像需要在特定时间更新，例如在调整 PictureBox 大小时。在调整大小事件中，添加：

PictureBox1.Invalidate       ' tell windows it needs to be redrawn
' or
PictureBox1.Refresh          ' redraw now

Me.Refresh 有点矫枉过正，因为整个表单可能不需要重新绘制。

Answer 2

正如汉斯·帕桑特所说。先摆脱；

Private g As Graphics

以及整个PictureBox1_Resize(...)... 例程。然后把下面的套路改成这样；

Private Sub Form1_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles MyBase.Paint
    DisplayMyStuff(e.Graphics)
End Sub

和

Private Sub DisplayMyStuff(pGraphics As Graphics)
    Dim pt1 As New Point(50, 50)
    Dim pt2 As New Point(100, 100)
    Dim pt3 As New Point(150, 150)
    Dim pictBoxSize As New Size(CType(PictureBox1.Size, Point))
    Dim width As Integer = CInt(pictBoxSize.Width / 2)
    Dim height As Integer = CInt(pictBoxSize.Height / 2)
    Dim sz As New Size(width, height)

    pGraphics.Clear(Color.Bisque)

    Dim rect1 As New Rectangle(pt1, sz)
    Dim rect2 As New Rectangle(pt2, sz)
    Using linGradBr As New LinearGradientBrush(pt2, pt3, Color.Yellow, Color.Blue)
        pGraphics.FillRectangle(Brushes.Red, rect1)
        pGraphics.FillRectangle(linGradBr, rect2)
    End Using
End Sub

.. 然后测试。请回来告诉我你学到了一些东西！特别是..您不需要创建新的红色画笔 - 所有“标准”颜色都是内置的 - 并且正确使用图形对象可以带来更好、更流畅的显示。