你如何将文本数据保存到二进制文件中以使其不可读

Question

好吧，我只是无法在整个网络上找到一个好的简单示例来帮助我实现我的目标，而无需学习有关 vbnet 某些主题的全新章节。 我想保存重要的“设置”，例如用户计算机可以用来从他们的计算机访问远程服务器的管理密码。

在示例中，只要数据不是诸如“这是我的密码”之类的文本但不会显示 1232.78 或布尔值之类的数字，我的程序就可以正常工作

纯文本，即可以使用记事本从文件中轻松读取字符串。

有没有办法避免在二进制文件中显示明显可见的文本数据？

      Imports System
      Imports System.IO
      Public Class Form2

      Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click


    Const fileName As String = "AppSettings.txt"

    Using writer As BinaryWriter = New BinaryWriter(File.Open(fileName, FileMode.Create))
        writer.Write("This is my secret password")
        writer.Write(1.25F)
        writer.Write("c:\Temp")
        writer.Write(10)
        writer.Write(True)
    End Using



 End Sub

 end class

当我用记事本打开我的文件 AppSettings.txt 时，它会显示

              This is my secret password   ?c:\Temp

还有其他一些无法在此处显示的字符。 当我读取文本文件时，文本文件中的所有数据都能正确读取。

那么我如何让程序用户看不到二进制文本文件的人类可读信息？

Answer 1

写入二进制文件时，文本不会被混淆。从技术上讲，您视为奇数字符的数字也不是不可读的 - 如果有人知道数据类型，他们可以计算出值。

为了使其不可读，您可以逐个加密每个字符串（如建议的欺骗链接中所示），或将您的流“包装”在Cryptostream 中。由于您希望BinaryWriter 会为您做一些伪加密，您可以完全跳过它。另一种选择是将信息存储在一个类中并使用CryptoStream 将其序列化以将其写出。

下面的代码使用类来保存这些不同的设置，并使用BinaryFormatter 来序列化类。序列化器将避免必须逐位写出数据，如果您扩展或更改要保存的数据，只需修改类，而不是加密代码。服务器信息类：

<Serializable>
Public Class SvrSettings
    Public Property Server As String
    Public Property UserName As String
    Public Property Password As String

    Public Property SomeInt As Int32
    Public Property SomethingElse As DateTime
    ' add anything else to be encrypted
End Class

' elsewhere put the data to save/encrypt in an instance:
SvrData = New SvrSettings
SvrData.UserName = "admin"
SvrData.Password = "some password"
SvrData.SomeInt = 42
SvrData.SomethingElse = DateTime.Now
SvrData.Server = "addressof(mysvr)"

保存到加密的二进制文件。您将需要一些新的 Imports：

Imports System.Security.Cryptography
Imports System.Runtime.Serialization.Formatters.Binary
'...
Dim password As String = "AWeakPassword"

Dim key As Byte() = Encoding.UTF8.GetBytes(password)
Dim iv(15) As Byte
    Using rng As New RNGCryptoServiceProvider
    rng.GetNonZeroBytes(iv)
End Using

Using rijAlg = Rijndael.Create()
    rijAlg.Padding = PaddingMode.ISO10126

    ' USING encryptor AND filestream
    Using encryptor As ICryptoTransform = rijAlg.CreateEncryptor(key, iv),
            fs As New FileStream("C:\Temp\crypto.bin",
                                 FileMode.OpenOrCreate Or FileMode.Truncate)
        ' save iv to "naked" filestream
        fs.Write(iv, 0, iv.Length)
        Using cs As New CryptoStream(fs, encryptor, CryptoStreamMode.Write)
            Dim bf As New BinaryFormatter
            bf.Serialize(cs, SvrData)
            ' may not be needed - doesnt hurt
            cs.FlushFinalBlock()
        End Using
    End Using
End Using

序列化意味着该类中的所有数据都一次保存。 CryptoStream 包装 FileStream 并进行实际加密。

您将需要iv 来读回数据，但不必将其存储在某个地方，而是在将其包装到CryptoStream 之前将其写入文件流。回读：

' read back to a new instance
Dim newSvrData As SvrSettings

Using rijAlg = Rijndael.Create()
    rijAlg.Padding = PaddingMode.ISO10126

    Using fs As New FileStream("C:\Temp\crypto.bin", FileMode.Open)
        ' read the IV first
        fs.Read(iv, 0, iv.Length)
        ' USING encryptor AND CryptoStream
        Using encryptor As ICryptoTransform = rijAlg.CreateDecryptor(key, iv),
            cs As New CryptoStream(fs, encryptor, CryptoStreamMode.Read)
            Dim bf As New BinaryFormatter
            newSvrData = CType(bf.Deserialize(cs), SvrSettings)
        End Using
    End Using
End Using

' test if the data made the round trip:
Console.WriteLine(newSvrData.UserName)
Console.WriteLine(newSvrData.Password)
Console.WriteLine(newSvrData.Server)
Console.WriteLine(newSvrData.SomethingElse)

测试结果：

管理员
一些密码
地址(mysvr)
2016 年 2 月 6 日下午 13:56:44

您可以通过将二进制写入器包装在CryptoStream 中来执行类似的操作。序列化一个对象的价值在于只需一行代码就可以保存所有的值。