动态打开表单

Question

我有一个名为 TopicBar 的第三方控件，它看起来像你可以在窗口左侧看到的 windows xp 导航栏

在我的应用程序中，我有 71 个表单，我创建了一个数据库表来存储我的所有表单 Name 和 Text，特定用户可以添加哪些表单（通过搜索我已经存储在表中的表单名称) 应作为项目添加到主题栏中。

例如，一个名为 FrmBill 的表单，它的名称是 Bill，一旦用户将 Bill 添加到 Topicbar，它将成功创建一个名为 Bill 的项目，现在我面临的是我需要在该用户单击时打开表单 FrmBill在主题栏中的账单项上

我可以获取表单名称，即 FrmBill 是用户在 Bill 中点击，但我无法打开表单，因为我需要在此处动态创建实例或调用表单 frmBill

到目前为止我做了什么

 Dim formName As String
    Dim frm As Form

Using conn As New SqlConnection(conn_str)
    conn.Open()
    Dim cmd As SqlCommand
    cmd = New SqlCommand("", conn)
    cmd.CommandText = "select top 1 formname from winforms where id=" & winformid & ""
    formName = cmd.ExecuteScalar
    'output: FrmBill
    frm = New Form
    frm.Name = formName '(FrmBill)

    With frm
        .MdiParent = FrmMain
        .Show()
        .Focus()
    End With

End Using

注意：在这个函数中，我可以从数据库中获取表单名称，即FrmBill，但它没有显示实际的表单FrmBill

那么无论如何都要像下面这样声明表单名称

dim frm as new "& formname &"

Answer 1

这并不像“dim frm as new”& formname &“”那么简单，但是可以这样做：

Dim frmNewForm As Form = Nothing
Dim frmNewForm_Type As Type = Type.GetType("your_assembly.type_name")
frmNewForm = CType(Activator.CreateInstance(frmNewForm_Type), Form)

我的意思是，你必须存储类表单的类型。

编辑：

您可以这样打开一个表单：

Dim oFr as New frmBill
oFr.Show()

好吗？好。您可以这样打开一个表单：

 Dim oFr as Form 
 oFr = New frmBill ' Because frmBill inherits System.Windows.Forms.Form class. All forms do it
 oFr.Show()

这里，frmBill 是类的类型。您没有 frmBill 显式引用，因此您必须动态加载它。

怎么可能呢？使用称为反射的“NET 机制”。您可以动态地创建一个类，指定类类型。

Dim frmNewForm As Form = Nothing
Dim frmNewForm_Type As Type = Type.GetType("project_name.frmBill")
frmNewForm = CType(Activator.CreateInstance(frmNewForm_Type), Form)

Plutonix 在说什么？假设您在 frmBill 中有一个公共的“打印”方法。
根据我的回答，你不能这样做：

frmNewForm.print()

因为你只能访问 System.Windows.Forms.Form 方法（close、show、showdialog...）

您可以根据需要使用自定义基类、接口或基本抽象类...来改进这一点。您可以根据需要组合不同的想法。例如，您可以将接口与超类结合起来：

public class frmMyForms
   inherits System.Windows.Forms.Form 

   public sub store_data ()  

....

public interface IInterface_common_methods

 sub print ()

...

public class frmBill
   inherits frmMyForms
   implements IInterface_common_methods

   public overloads sub store_data ()  
     msgbox ("store")
   end sub

 public sub print  ()  implements IInterface_common_methods.print
     msgbox ("print")
   end sub

现在，您可以执行以下操作：

Dim frmNewForm As frmMyForms= Nothing
Dim frmNewForm_Type As Type = Type.GetType("project_name.frmBill")
frmNewForm = CType(Activator.CreateInstance(frmNewForm_Type), frmMyForms)       

frmNewForm.Show()
frmNewForm.store_data() 
ctype(frmNewForm, IInterface_common_methods).Print() 

我不知道这是否是您正在寻找的东西，但我希望这可以帮助您了解有关 NET 可能性的更多信息。