Excel Range 中的一维数组

Question

我目前正在使用以下代码填充我的数组 Securities：

Option Base 1
Securities = Array(Worksheets(3).Range("A8:A" & SymbolCount).Value)

这会产生一个二维数组，其中每个地址都是 (1...1,1...N)。我想要一个一维数组 (1...N)。

我怎样才能 (a) 将 Securities 填充为一维数组，或者 (b) 有效地将 Securities 剥离为一维数组（我在每个循环中都遇到了问题）。

Answer 1

我知道您已经接受了答案，但这里有更简单的代码：

如果您要抓取单行（多列），请使用：

Securities = application.transpose(application.transpose _
             (Worksheets(3).Range("A8:A" & SymbolCount).Value))

如果您要获取单列（多行），请使用：

Securities = application.transpose(Worksheets(3).Range("A8:A" & SymbolCount).Value)

所以，基本上你只需为行转置两次，为列转置一次。

更新：

大表可能不适用于此解决方案（如下评论中所述）：

我在一个大表中使用了这个方案，发现这个技巧有一个限制：Application.Transpose(Range("D6:D65541").Value)'runs without error，但是Application.Transpose(Range("D6:D65542").Value)'run-time error 13 Type mismatch

更新 2：

您可能在 cmets 中提到的另一个问题：

如果超过 255 个字符，则函数失败。

我已经很久没有使用 Excel VBA 了，但这可能是以这种方式访问​​数据的一般限制？

Answer 2

Sub test2()
    Dim arTmp
    Dim securities()
    Dim counter As Long, i As Long
    arTmp = Range("a1").CurrentRegion
    counter = UBound(arTmp, 1)
    ReDim securities(1 To counter)
    For i = 1 To counter
        securities(i) = arTmp(i, 1)
    Next i
    MsgBox "done"
End Sub

Answer 3

这将反映 iDevlop 给出的答案，但我想为您提供一些关于它的作用的更多信息。

Dim tmpArray As Variant
Dim Securities As Variant

'Dump the range into a 2D array
tmpArray = Sheets(3).Range("A8:A" & symbolcount).Value

'Resize the 1D array
ReDim Securities(1 To UBound(tmpArray, 1))

'Convert 2D to 1D
For i = 1 To UBound(Securities, 1)
    Securities(i) = tmpArray(i, 1)
Next

从范围中获取一维数组的最快方法可能是将范围转储到二维数组中并将其转换为一维数组。这是通过声明第二个变体并在将范围转储到第一个变体后使用ReDim 将其重新调整为适当的大小来完成的（请注意，您不需要使用 Array()，您可以像我一样执行此操作上面有，比较清楚）。

您只需遍历 2D 数组，将每个元素放入 1D 数组中。

我希望这会有所帮助。

Answer 4

如果您将单个列中的值按原样读取到数组中，那么我认为您最终会得到一个需要使用 array(1, n) 语法访问的数组。

或者，您可以遍历数据中的所有单元格并将它们添加到数组中：

Sub ReadIntoArray()
    Dim myArray(), myData As Range, cl As Range, cnt As Integer, i As Integer
    Set myData = Worksheets(3).Range("A8:A" & SymbolCount) //Not sure how you get SymbolCount

    ReDim myArray(myData.Count)

    cnt = 0
    For Each cl In myData
        myArray(cnt) = cl
        cnt = cnt + 1
    Next cl

    For i = 0 To UBound(myArray) //Print out the values in the array as check...
        Debug.Print myArray(i)
    Next i
End Sub