如何使用 XSLT 获得相似的属性

Question

我有一个类似的 XML 文件

<node>
  <properties>
    <property name="titleENG">English title</property>
    <property name="titleFRE">French title</property>
    <property name="descENG">English description</property>
    <property name="descFRE">French description</property>
    ...
  </properties>
</node>

作为输出，我想要一个类似的 CSV 文件

title, English title, French title
desc, English description, French description
...

假设我知道可用的语言，但我不知道可用的属性（title、desc、...）

我可以用下面的 XSLT 得到英文字符串

<?xml version="1.0" encoding="ISO-8859-1"?>
  <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >

  <xsl:template match="@* | node()">
    <xsl:apply-templates select="@* | node()"/>
  </xsl:template>

  <xsl:template match="property">
    <xsl:if test="@name[ends-with(.,'ENG')]">
      <xsl:variable name="key" select="substring(@name,1,string-length(@name)-3)" />
      <xsl:value-of select="$key"/>, <xsl:value-of select="./text()"/><xsl:text>&#10;     </xsl:text>
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>

但是在'if'里面，我还需要name=concat($key,'FRE')的属性值，我该怎么做呢？ 任何帮助表示赞赏。

编辑 我想我可以将我的问题改写为（因为我可以轻松地将我当前的集合转换为这个）：假设我有一个类似的 XML

<node>
 <properties>
  <property name="dummy"></property>
  <property name="title" lang="ENG">English title</property>
  <property name="title" lang="FRE">French title</property>
  <property name="desc" lang="ENG">English description</property>
  <property name="desc" lang="FRE">French description</property>
  ...
 </properties>
</node>

在这种情况下，如何创建包含两行的 (CSV) 输出，第一列中的名称和下一列中的英语、法语翻译？

Answer 1

XSLT 2.0 还可以

实际上，我没有时间切换到 XSLT 2.0 模式，这两种模式都适用：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:my="http://www.example.com/my">

<xsl:output method="text" encoding="UTF-8"/>

<xsl:variable name="root" select="/" />

<xsl:key name="prop-by-prefix" match="property" use="substring(@name, 1, string-length(@name)-3)" />
<xsl:key name="prop-by-name" match="property" use="@name" />

<my:languages>
    <lang>ENG</lang>
    <lang>FRE</lang>
</my:languages>

<xsl:template match="/">
    <xsl:for-each select="node/properties/property[count(. | key('prop-by-prefix', substring(@name, 1, string-length(@name)-3))[1]) = 1]">
        <xsl:variable name="prefix" select="substring(@name, 1, string-length(@name)-3)" />
        <xsl:value-of select="$prefix"/>
        <xsl:text>,</xsl:text>
        <xsl:for-each select="document('')/xsl:stylesheet/my:languages/lang">
            <xsl:variable name="name" select="concat($prefix, .)"/>
            <!-- switch context back to source document in order to use key -->
            <xsl:for-each select="$root">
                <xsl:value-of select="key('prop-by-name', $name)"/>
            </xsl:for-each>
            <xsl:if test="position()!=last()">
                <xsl:text>,</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:if test="position()!=last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

应用于您的输入：

<node>
  <properties>
    <property name="titleENG">English title</property>
    <property name="titleFRE">French title</property>
    <property name="descENG">English description</property>
    <property name="descFRE">French description</property>
  </properties>
</node>

得到如下结果：

title,English title,French title
desc,English description,French description

---

补充：

我刚刚注意到您更改了输入。这使它变得更加简单：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="UTF-8"/>

<xsl:key name="prop-by-name" match="property" use="@name" />

<xsl:template match="/">
    <xsl:for-each select="node/properties/property[count(. | key('prop-by-name', @name)[1]) = 1][@lang]">
        <xsl:value-of select="@name"/>
        <xsl:text>,</xsl:text>
        <xsl:for-each select="key('prop-by-name', @name)">
            <xsl:value-of select="."/>
            <xsl:if test="position()!=last()">
                <xsl:text>,</xsl:text>
            </xsl:if>
        </xsl:for-each>
        <xsl:if test="position()!=last()">
            <xsl:text>&#10;</xsl:text>
        </xsl:if>
    </xsl:for-each>
</xsl:template>
</xsl:stylesheet>

如果您使用的是 XSLT 2.0（或支持 EXSLT set:distinct) 函数的 XSLT 1.0 处理器），则可以使用它来代替 Muenchian 分组。

Answer 2

您可以在 if 之外声明您的 $key 变量：

<xsl:variable name="key" select="substring(@name,1,string-length(@name)-3)" />

并在@name 属性中使用substring-after 和$key 获取后缀：

<xsl:variable name="suffix" select="substring-after(@name, $key)"/>

然后您可以在不知道后缀的情况下独立进行测试：

<xsl:if test="@name[ends-with(.,$suffix)]">