在 Perl 中，如何从正则表达式中获取匹配的子字符串？

Question

我的程序读取其他程序的源代码并收集有关使用的 SQL 查询的信息。我在获取子字符串时遇到问题。

...
$line = <FILE_IN>;
until( ($line =~m/$values_string/i && $line !~m/$rem_string/i) || eof )
{
   if($line =~m/ \S{2}DT\S{3}/i)
   {

   # here I wish to get (only) substring that match to pattern \S{2}DT\S{3} 
   # (7 letter table name) and display it.
      $line =~/\S{2}DT\S{3}/i;
      print $line."\n";
...

结果打印打印整行而不是我期望的子字符串。我尝试了不同的方法，但我很少使用 Perl，并且可能会犯基本概念错误。 （行中表名的位置不固定。另一个问题是多次出现，即[... SELECT * FROM AADTTAB, BBDTTAB, ...] ）。如何获取该子字符串？

Answer 1

使用带括号的分组并存储第一组。

if( $line =~ /(\S{2}DT\S{3})/i )
{
  my $substring = $1;
}

上面的代码修复了提取第一个表名的直接问题。但是，问题还询问如何提取所有表名。所以：

# FROM\s+     match FROM followed by one or more spaces
# (.+?)       match (non-greedy) and capture any character until...
# (?:x|y)     match x OR y - next 2 matches
# [^,]\s+[^,] match non-comma, 1 or more spaces, and non-comma
# \s*;        match 0 or more spaces followed by a semi colon
if( $line =~ /FROM\s+(.+?)(?:[^,]\s+[^,]|\s*;)/i )
{
  # $1 will be table1, table2, table3
  my @tables = split(/\s*,\s*/, $1);
  # delim is a space/comma
  foreach(@tables)
  {
     # $_ = table name
     print $_ . "\n";
  }
}

结果：

如果 $line = "SELECT * FROM AADTTAB, BBDTTAB;"

输出：

AADTTAB
BBDTTAB

如果 $line = "SELECT * FROM AADTTAB;"

输出：

AADTTAB

Perl 版本：为 MSWin32-x86-multi-thread 构建的 v5.10.0

Answer 2

我更喜欢这个：

my ( $table_name ) = $line =~ m/(\S{2}DT\S{3})/i;

这个

1. 扫描$line并捕获与模式对应的文本
2. 将“所有”捕获 (1) 返回到另一侧的“列表”。

这个伪列表上下文是我们捕获列表中第一项的方式。它与传递给子例程的参数的方式相同。

my ( $first, $second, @rest ) = @_;


my ( $first_capture, $second_capture, @others ) = $feldman =~ /$some_pattern/;

注意：：也就是说，您的正则表达式过多地假设文本在少数情况下有用。 没有捕获任何没有 dt 的表名，如 7 个位置中的第 3 和第 4 位？ 这对于 1）快速和肮脏的，2）如果你对有限的适用性没问题.

Answer 3

如果它遵循FROM，则匹配模式会更好。我假设表名仅由 ASCII 字母组成。在这种情况下，最好说出你想要的。撇开这两条评论，请注意，在列表上下文中成功捕获正则表达式匹配会返回匹配的子字符串。

#!/usr/bin/perl

use strict;
use warnings;

my $s = 'select * from aadttab, bbdttab';
if ( my ($table) = $s =~ /FROM ([A-Z]{2}DT[A-Z]{3})/i ) {
    print $table, "\n";
}
__END__

输出：

C:\Temp> s
aadttab

根据您系统上perl 的版本，您可以使用命名的捕获组，这可能会使整个内容更易于阅读：

if ( $s =~ /FROM (?<table>[A-Z]{2}DT[A-Z]{3})/i ) {
    print $+{table}, "\n";
}

见perldoc perlre。

Answer 4

Parens 可以让您将正则表达式的一部分放入特殊变量中：$1、$2、$3... 所以：

$line = ' abc andtabl 1234';
if($line =~m/ (\S{2}DT\S{3})/i)   {   
    # here I wish to get (only) substring that match to pattern \S{2}DT\S{3}    
    # (7 letter table name) and display it.      
    print $1."\n";
}

Answer 5

使用捕获组：

$line =~ /(\S{2}DT\S{3})/i;
my $substr = $1;

Answer 6

$& 包含最后一个模式匹配的字符串。

例子：

$str = "abcdefghijkl";
$str =~ m/cdefg/;
print $&;
# Output: "cdefg"

所以你可以做类似的事情

if($line =~m/ \S{2}DT\S{3}/i) {
    print $&."\n";
}

警告：

如果您在代码中使用$&，它将减慢所有模式匹配。