使用 Perl 正则表达式进行重叠文本替换

Question

我有一个包含一堆句子的文本文件。句子包含空格（空格、制表符、换行符）以分隔由字母和/或数字组成的单词。 我想找到单词“123”或“-123”并在数字开始前插入一个点 (.)。因此，所有出现的“123”和“-123”都将转换为“.123”和“-.123”。

我正在尝试以下方法：

$line =~ s/(\s+-*123\s+)/getNewWord($1)/ge

其中 $line 包含从文件中读取的一行，getNewWord word 函数会将点 (.) 放在匹配单词的适当位置。

但它不适用于有两个连续的“123”如“123 123”的情况。由于第一个“123”被替换为“.123”，因此单词后面的空格已经匹配，而第二个“123”不匹配，因为正则表达式引擎无法将前面的空格与该单词匹配。

谁能帮我解决这个问题？谢谢！

Answer 1

我同意 MRAB 的观点（并为他/她的回答 +1），但实际上并不需要 getNewWord 函数。我会将整个语句更改为以下内容之一：

$line =~ s/((?:^|\s)-?)(123)(?=\s|$)/$1.$2/g;

$line =~ s/(?:^|(?<=\s))(-?)(123)(?=\s|$)/$1.$2/g;

$line =~ s/(?:^|(?<=\s)|(?<=\s-))(?=123(?:\s|$))/./g;

Answer 2

它可能会稍微快一些（没有显式捕获）并且它允许文件没有前导/尾随空格：

$ echo '123 -123 -123  123' | perl -pe's/(?:^|\s+)\K(?=-?123\b)/./g'
.123 .-123 .-123  .123

将. 放在- 之后：

$ echo '123 -123 -123  123' | perl -pe's/(?:^|\s+)-*\K(?=123\b)/./g'
.123 -.123 -.123  .123

Answer 3

尝试使用像这样的积极前瞻：(\s+-*123)(?=\s)。

Answer 4

这让我想起了这个问题：Search html file for random string using regex，在那里我发现（显示）否定环视断言的一个很好的用途，即匹配可选分隔符和避免部分匹配。

匹配-?123很简单，问题是

1. 部分字符串不匹配
2. 避免行首/行尾不匹配
3. 避免移动 \G 锚点
4. 对可选破折号-? 进行后向断言

我没有设法解决 #4，因为不支持可变长度后向断言，所以修复是使用捕获组。

请注意，此问题的其他一些答案并未解决这些问题。

说明：

非空白的否定后向断言匹配空白和字符串的开头，并确保我们不匹配部分字符串。然后跟随捕获组中的可选破折号。匹配的结尾是嵌套的前瞻，我们必须匹配123，后跟任何非非空白字符。

代码：

use strict;
use warnings;

while(<DATA>) {
    s/(?<!\S)(-?)(?=123(?!\S))/$1./g;
    print;
}

__DATA__
r 123 z123 "123" -1233 d123 123-123
123 -123 -123 123 123

输出：

r .123 z123 "123" -1233 d123 123-123
.123 -.123 -.123 .123 .123

Answer 5

或者只是这个？这不会打扰空格，并且适用于 perl 5.8。

echo '123 -123 -123  123' | perl -pe's/(-)?(123)/$1.$2/g'