如何合并以特定子字符串开头的行？

Question

我有一个这样的文件

$ head test
                     gene=ENSECAG00000012421
                     note="synaptonemal complex central element protein 1
                     [Source:HGNC Symbol;Acc:28852]"
                     gene=ENSECAG00000017803
                     note="Uncharacterized protein
                     [Source:UniProtKB/TrEMBL;Acc:F6SNR9]"
                     gene=ENSECAG00000019088
                     note="cytochrome P450 2E1  [Source:RefSeq
                     peptide;Acc:NP_001104773]"
                     gene=ENSECAG00000004229

我想让这个文件看起来像这样

ENSECAG00000012421    synaptonemal complex central element protein 1 [Source:HGNC Symbol;Acc:28852]
ENSECAG00000017803    Uncharacterized protein [Source:UniProtKB/TrEMBL;Acc:F6SNR9]

我不确定 note 是否总是在两行中，所以我想要一些类似于

的内容

awk '{if(substr($1,1,4)=="gene") gene=$1; else print gene,$1}'

但我希望它能够识别它可能在两行中，并且单词之间也有空格。所以我希望它将“”中的所有内容打印为第 2 列（理想情况下用 \t 分隔 2 列，这样以后就不会混淆） 我知道如何去掉基因和注释和“，但不确定它们是否有助于识别。 我很高兴它是一串不同的命令，首先将整个音符放在一行中，然后将它与基因或所有内容一次性结合起来，无论哪种效果最好。

另外，如果您使用的是 awk，能否简要说明您在做什么？

感谢您的帮助！

Answer 1

如果您有GNU awk 或mawk（该解决方案依赖于基于正则表达式的输入记录分隔符，严格符合POSIX 或更早的awk 实现不支持）：

短版：

awk -v RS=' *(gene=|note="|")' '
  { gsub("\n", ""); if ($0 == "") next; $1=$1; 
    printf "%s%s", $0, (/^ENSECAG[0-9]+$/ ? "\t" : "\n") }
  ' file

注释版：

-v RS=' *(gene=|note="|")' - RS 是一个特殊变量，用于定义输入记录分隔符 - 指定一个正则表达式，将输入分成感兴趣的记录 - 跨行。

awk -v RS=' *(gene=|note="|")' '
  {    
   gsub("\n", "");     # remove all newlines from record
   if ($0 == "") next  # ignore empty records
   $1=$1;              # rebuild record to compress multiple interior spaces
    # Output:
    #  - Is it a gene record, i.e. is there only 1 field that contains a gene name?
    #    Output it with just a trailing \t, but no trailing \n, so that the next
    #    note record will print on the same line.
    #  - Otherwise: a note record: print with trailing \n, effectively
    #    appending it to the previous gene record.
   printf "%s%s", $0, (/^ENSECAG[0-9]+$/ ? "\t" : "\n")
  }
  ' file

Answer 2

可能过于复杂，但这里有一种方法：

/^\s*gene=/  { gene=substr($1, 6) }
/^\s*note=/  { note=substr($0, 28) }
/"$/         { if (substr($1,1,4)=="note")
                 print gene, substr($0, 28, length($0)-28);
               else
                 print gene, note, substr($0, 22, length($0)-22) }

请注意，这同时处理单行和两行注释。

Answer 3

使用 awk

awk 'BEGIN{FS="\n";RS="gene="}{gsub(/(note=|\")/,"");print $1,$2,$3}' file|awk '$1=$1'

ENSECAG00000012421 synaptonemal complex central element protein 1 [Source:HGNC Symbol;Acc:28852]
ENSECAG00000017803 Uncharacterized protein [Source:UniProtKB/TrEMBL;Acc:F6SNR9]
ENSECAG00000019088 cytochrome P450 2E1 [Source:RefSeq peptide;Acc:NP_001104773]
ENSECAG00000004229

Answer 4

 sed -n 'N;;/"$/!N;s/\n//g;p' input | \
   sed 's/.*gene=//;s/[ \t]*note="\([^"]*\)"/\t\1 /;s/  */ /g'

给予：

ENSECAG00000012421  synaptonemal complex central element protein 1 [Source:HGN...
ENSECAG00000017803  Uncharacterized protein [Source:Uni...
ENSECAG00000019088  cytochrome P450 2E1 [Source:Ref...

Answer 5

$ awk '{$1=$1; gsub(/"/,""); sub(/^note=/,""); pfx=(sub(/^gene=/,"")?(NR>1?ORS:""):OFS); printf "%s%s",pfx,$0} END{print ""}' file
ENSECAG00000012421 synaptonemal complex central element protein 1 [Source:HGNC Symbol;Acc:28852]
ENSECAG00000017803 Uncharacterized protein [Source:UniProtKB/TrEMBL;Acc:F6SNR9]
ENSECAG00000019088 cytochrome P450 2E1 [Source:RefSeq peptide;Acc:NP_001104773]
ENSECAG00000004229