用于向后测试所有可能日期的 Perl 脚本

Question

我在网上找到了这个代码 (Source) 来下载必应图片。

这个 perl 脚本下载今天的 Bing 壁纸图片，我如何更改它以向后测试所有可能的日期？什么时候停止都没关系，因为我要手动停止。

我尝试了一些选项，但我不知道 perl，而且有点令人沮丧。

非常感谢！

#!/usr/bin/perl
$\="\n";
use strict;
use warnings;
use Data::Dumper;
use LWP::Simple;
use JSON;
use POSIX qw/strftime/;
 
my $base_url = "http://www.bing.com/";
my $json_url = "http://www.bing.com/HPImageArchive.aspx?format=js&n=1&mkt=en-US";
my $output_dir = "C:\\Downloads\\Wallpaper";
 
my $content = get($json_url)
  or die "Failed to retrieve $json_url! $! $@";
  
my $json = from_json($content)
  or die "Failed to parse json response! $! $@";
  
my $image_url = $base_url . $json->{images}[0]->{url};
print "Today's Image: $image_url";
 
my $date = strftime('%Y_%m_%d',localtime);
my $filename = "$output_dir\\$date.jpg";
print $filename;
 
my $status = getstore($image_url,$filename);
if($status == 200)
{
  print "HTTP Response OK.";
  my $size = -s $filename;
  if($size > 0)
  {
    print "Retrieved $size bytes.";
  }
  elsif($size == 0)
  {
    print "Seems we have retrieved a zero-byte image.";
  }
}
else
{
  print "HTTP Response: $status";
}```

Answer 1

这个 perl 脚本下载今天的 Bing 壁纸图片，我如何更改它以向后测试所有可能的日期？

我的意思是：我想下载过去几天的图片。
不幸的是，这里只提供了最后 8 张图片。 - 您在初始请求中使用了足够大的n，然后循环遍历结果。
日期已经在 json 中了，所以不需要日期模块。

#!/usr/bin/perl
$\="\n";
use strict;
use warnings;
use Data::Dumper;
use LWP::Simple;
use JSON;
use POSIX qw/strftime/;
use Data::Dumper;
my $base_url = "http://www.bing.com/";
my $json_url = "http://www.bing.com/HPImageArchive.aspx?format=js&n=100&mkt=en-US";
my $output_dir = "C:\\Downloads\\Wallpaper";
 
my $content = get($json_url)
  or die "Failed to retrieve $json_url! $! $@";
  
my $json = from_json($content)
    or die "Failed to parse json response! $! $@";
print Dumper $json;

my $images = $json->{images};
for my $image (@$images) {
    my $image_url = $base_url . $image->{url};

    my $date = $image->{startdate};
    $date =~ s/(\d{4})(\d{2})(\d{2})/$1_$2_$3/;
    my $filename = "$output_dir\\$date.jpg";
    print $filename;
 
    my $status = getstore($image_url,$filename);
    if ($status == 200) {
        print "HTTP Response OK.";
        my $size = -s $filename;
        if ($size > 0) {
            print "Retrieved $size bytes.";
        } elsif ($size == 0) {
            print "Seems we have retrieved a zero-byte image.";
        }
    } else {
        print "HTTP Response: $status";
    }
}

Answer 2

使用模块进行日期时间操作。 DateTime 是一个自然的选择，作为最完整、最圆润的日期时间库，具有非常一致的界面和行为。

这是一个非常粗略的示例，向后迭代数天

use warnings;
use strict;
use feature 'say';

use DateTime;
use DateTime::Format::Strptime;

my $date_stop = shift // '2021-02-01';  # input format: yyyy-mm-dd 

my $dt = DateTime->today(time_zone => 'local');

my $dt_stop = DateTime::Format::Strptime->new(
    pattern => '%Y-%m-%d',
    time_zone => 'local',
    on_error => 'croak',
)->parse_datetime($date_stop)->truncate(to => 'day');


while ($dt >= $dt_stop) { 
    say $dt->ymd('-');
    $dt->subtract(days => 1); 
}

虽然这可以正常工作，但其中隐藏着一些功能和微妙之处。请参阅文档。

我使用local 时区；适当调整。我将truncate 设置为天，通过使用today（这样做）并显式截断从格式创建的对象，将时间分量设置为零。如果您需要/想要时间进行调整，请注意这确实会影响比较（和计算），因此请仔细考虑您需要什么。

我使用DateTime::Format::Strptime 来展示如何使用各种格式（几乎全部来自strptime(3)）来启动对象，而DateTime 本身对我们没有用处。