Invocablemethod Apex 类汇总多个货币字段答案

【问题标题】：Invocablemethod Apex Class Rollup Multiple Currency FieldsInvocablemethod Apex 类汇总多个货币字段
【发布时间】：2020-09-14 00:55:47
【问题描述】：

我正在编写一个可调用方法批处理顶点类，以将“订单包”对象上的多个货币字段汇总到其“订单位置”的父对象。我以为我已经正确添加了所有内容，但它似乎正在将“Package_Monthly_Recurring_Fees__c”和“Package_One_Time_Fees__c”从 Package_Monthly_Recurring_Fees__c 字段更新为相同的价格。有人可以帮我确定为什么两个字段使用相同的价格吗？非常感谢任何帮助！

global class OrderLocationRollupSummary implements Database.Batchable<sObject>, Schedulable {
    
        //Invocable Method
        @InvocableMethod(label='Rollup All Order Packages to Locations')
        global static void rollupAllorderpackages(List<Order_Location_Package__c> orderpackages) {
            rollupOrderPackages(orderpackages);
        }
    
        //Batchable Methods
        global Database.QueryLocator start(Database.BatchableContext bc) {
            return Database.getQueryLocator([SELECT Id FROM Order_New_Location__c]);
        }
    
        global void execute(Database.BatchableContext context, List<sObject> batch){
            Set<Id> OrderLocationIds = new Set<Id>();
    
            for (sObject ordloc : batch) {
                OrderLocationIds.add(ordloc.Id);
            }
    
            summarizeOrderPackages(OrderLocationIds);
        }
    
        global void finish(Database.BatchableContext context) {}
    
        //Schedulable Methods
        global void execute(SchedulableContext context){
            OrderLocationRollupSummary batchJob = new OrderLocationRollupSummary();
            Database.executeBatch(batchJob);
        }
    
        //Static Methods
        public static void rollupOrderPackages(List<Order_Location_Package__c> orderpackages) {
            Set<Id> OrderLocationIds = new Set<Id>();
    
            //Get Order Location Ids from specified orderpackages
            for (Order_Location_Package__c ordpckg : orderpackages) {
                OrderLocationIds.add(ordpckg.New_Location_Name__c);
            }
    
            if (OrderLocationIds.isEmpty() == false) {
                /*Execute as a future call so that the user doesn't have to wait around for
                the rollup to finish. Unless, already in a future or batch call state then
                just perform the rollup.*/
                if (System.isFuture() == false && System.isBatch() == false) {
                    summarizeOrderPackagesAsync(OrderLocationIds);
                }
                else {
                    new OrderLocationRollupSummary().summarizeOrderPackages(OrderLocationIds);
                }
            }
        }
    
        @future
        public static void summarizeOrderPackagesAsync(Set<Id> OrderLocationIds) {
            new OrderLocationRollupSummary().summarizeOrderPackages(OrderLocationIds);
        }
    
        //Public Methods
        public void summarizeOrderPackages(Set<Id> OrderLocationIds) {
            //Get Order Locations to Update
            List<Order_New_Location__c> orderlocations = queryOrderLocationsById(OrderLocationIds);
    
            Map<Id, double> results = getOrderPackagesAmountsByLocationId(OrderLocationIds);
    
            //Loop Order Locations and set Amounts
            List<Order_New_Location__c> orderlocationsToUpdate = new List<Order_New_Location__c>();
            for (Order_New_Location__c ordloc : orderlocations) {
                double mrf = 0;
                double otf = 0;
    
                if (results.containsKey(ordloc.Id)) {
                    mrf = results.get(ordloc.Id);
                    otf = results.get(ordloc.Id);
                }
    
                //Determine if Amounts have Changed
                if (ordloc.Package_Monthly_Recurring_Fees__c != mrf || 
                    ordloc.Package_One_Time_Fees__c != otf) {
                    
                    ordloc.Package_Monthly_Recurring_Fees__c = mrf;
                    ordloc.Package_One_Time_Fees__c = otf;
                    orderlocationsToUpdate.add(ordloc); //Add location to collection to be updated
                }
            }
    
            if(orderlocationsToUpdate.isEmpty() == false) {
                Database.SaveResult[] saveResults = Database.update(orderlocationsToUpdate, false);
                System.debug(saveResults);
            }
        }
    
        //Private Methods
        public Map<Id, double> getOrderPackagesAmountsByLocationId(Set<Id> OrderLocationIds) {
            Map<Id, double> resultsByOrderLocationId = new Map<Id, double>();
    
            //Summarize Order Package Amounts by Order Location Id
            AggregateResult[] results = aggregateOrderPackageAmounts(OrderLocationIds);
            for (AggregateResult result : results) {
                Id orderlocationId = (Id) result.get('OrderLocation');
                double mrf = (double) result.get('MRFees');
                double otf = (double) result.get('OTFees');
    
                resultsByOrderLocationId.put(orderlocationId, mrf);
                resultsByOrderLocationId.put(orderlocationId, otf);
            }
            return resultsByOrderLocationId;
        }
    
        //Query Methods
        private List<Order_New_Location__c> queryOrderLocationsById(Set<Id> OrderLocationIds) {
            return [SELECT 
                    Id 
                    ,Package_Monthly_Recurring_Fees__c
                    ,Package_One_Time_Fees__c
                FROM 
                    Order_New_Location__c 
                WHERE 
                    Id IN :OrderLocationIds];
        }
    
        private AggregateResult[] aggregateOrderPackageAmounts(Set<Id> OrderLocationIds) {
            return [SELECT 
                     New_Location_Name__c OrderLocation
                    ,SUM(Monthly_Recurring_Fees__c) MRFees
                    ,SUM(One_Time_Fees__c) OTFees
                FROM 
                    Order_Location_Package__c
                WHERE
                    New_Location_Name__c IN :OrderLocationIds
                GROUP BY 
                    New_Location_Name__c];
        }
    
    }

【问题讨论】：

我对 Apex 有点陌生，因此我们将不胜感激。如果有更好的方法来写这个，我也会很感兴趣。我的主要目标是需要将多个货币字段汇总到父记录，但我需要尽可能接近实时地进行此操作，并且有时会更新 200 多个父记录（订单位置）。再次感谢您的指导！

标签： salesforce apex salesforce-development salesforce-developer

【解决方案1】：

在您的 summariseOrderPackages 方法中，以下代码将“mrf”和“oft”变量设置为相同的值。

        if (results.containsKey(ordloc.Id)) {
            mrf = results.get(ordloc.Id);
            otf = results.get(ordloc.Id);
        }

然后，您将相关字段设置为 mrf 和 otf 变量（具有相同的值）。

        //Determine if Amounts have Changed
        if (ordloc.Package_Monthly_Recurring_Fees__c != mrf || 
            ordloc.Package_One_Time_Fees__c != otf) {
            
            ordloc.Package_Monthly_Recurring_Fees__c = mrf;
            ordloc.Package_One_Time_Fees__c = otf;
            orderlocationsToUpdate.add(ordloc); //Add location to collection to be updated
        }

考虑在 OrderLocationRollupSummary 类中添加一个包装器和内部类来解决这个问题：

  public class Order_New_Location_Wrapper {
    Id orderlocationId = {get;set;}
    Double mrf = {get;set;}
    Double otf = {get;set;}
    public class Order_New_Location_Wrapper (Id arg1, Double arg2, Double arg3)
    orderlocationId = arg1;
    mrf = arg2;
    otf = arg3;
  }

然后在你的 getOrderPackagesAmountsByLocationId 方法中调用这个新的内部类：

public Map<Id, Order_New_Location_Wrapper> getOrderPackagesAmountsByLocationId(Set<Id> OrderLocationIds) {

//create a list of orderlocations to represent the collection objects coming from the wrapper 
        
        resultsByOrderLocationId = new Map<Id, Order_New_Location_Wrapper>();

        //Summarize Order Package Amounts by Order Location Id
        AggregateResult[] results = aggregateOrderPackageAmounts(OrderLocationIds);
        for (AggregateResult result : results) {
            Id orderlocationId = (Id) result.get('OrderLocation');
            double mrf = (double) result.get('MRFees');
            double otf = (double) result.get('OTFees');

            resultsByOrderLocationId.add(orderlocationId, new OpportunityWrapper(orderlocationId, mrg, otf));
        }
        return resultsByOrderLocationId;
    }

您还需要将 summariseOrderPackages 方法更新为如下所示：

public void summarizeOrderPackages(Set<Id> OrderLocationIds) {
    //Get Order Locations to Update
    List<Order_New_Location__c> orderlocations = queryOrderLocationsById(OrderLocationIds);

    Map<Id, Order_New_Location_Wrapper> results = getOrderPackagesAmountsByLocationId(OrderLocationIds);

    //Loop Order Locations and set Amounts
    List<Order_New_Location__c> orderlocationsToUpdate = new List<Order_New_Location__c>();
    for (Order_New_Location__c ordloc : orderlocations) {
        double mrf = 0;
        double otf = 0;

        if (results.containsKey(ordloc.Id)) {
            mrf = (Order_New_Location__c) results.get(ordloc.Id).mrf;
            otf = (Order_New_Location__c) results.get(ordloc.Id).otf;
        }

        //Determine if Amounts have Changed
        if (ordloc.Package_Monthly_Recurring_Fees__c != mrf || 
            ordloc.Package_One_Time_Fees__c != otf) {
            
            ordloc.Package_Monthly_Recurring_Fees__c = mrf;
            ordloc.Package_One_Time_Fees__c = otf;
            orderlocationsToUpdate.add(ordloc); //Add location to collection to be updated
        }
    }

    if(orderlocationsToUpdate.isEmpty() == false) {
        Database.SaveResult[] saveResults = Database.update(orderlocationsToUpdate, false);
        System.debug(saveResults);
    }
}

【讨论】：

感谢您的帮助！不过，我仍然有点困惑，我希望从 getOrderPackagesAmountsByLocationId 方法中提取聚合结果。我将如何分配正确的值？
我已更新答案以包含有关我的建议的更多详细信息。我没有尝试编译这个，所以它可能不是 100% 准确，但它应该提供这个想法。
太棒了！非常感谢！这是有道理的 - 我会试一试 - 再次感谢！
关于您创建的 Order_New_Location_Wrapper 是否可以提供更多指导？我似乎无法正确构建类以正确编译它。

【解决方案2】：

我可以通过更新我的一些方法来解决这个问题，见下文。再次感谢罗伯特的帮助！

global class OrderLocationRollupSummary implements Database.Batchable<sObject>, Schedulable {

//Invocable Method
@InvocableMethod(label='Rollup All Order Packages to Locations')
global static void rollupAllorderpackages(List<Order_Location_Package__c> orderpackages) {
    rollupOrderPackages(orderpackages);
}

//Batchable Methods
global Database.QueryLocator start(Database.BatchableContext bc) {
    return Database.getQueryLocator([SELECT Id FROM Order_New_Location__c]);
}

global void execute(Database.BatchableContext context, List<sObject> batch){
    Set<Id> OrderLocationIds = new Set<Id>();

    for (sObject ordloc : batch) {
        OrderLocationIds.add(ordloc.Id);
    }

    summarizeOrderPackages(OrderLocationIds);
}

global void finish(Database.BatchableContext context) {}

//Schedulable Methods
global void execute(SchedulableContext context){
    OrderLocationRollupSummary batchJob = new OrderLocationRollupSummary();
    Database.executeBatch(batchJob);
}

//Static Methods
public static void rollupOrderPackages(List<Order_Location_Package__c> orderpackages) {
    Set<Id> OrderLocationIds = new Set<Id>();

    //Get Order Location Ids from specified orderpackages
    for (Order_Location_Package__c ordpckg : orderpackages) {
        OrderLocationIds.add(ordpckg.New_Location_Name__c);
    }

    if (OrderLocationIds.isEmpty() == false) {
        /*Execute as a future call so that the user doesn't have to wait around for
        the rollup to finish. Unless, already in a future or batch call state then
        just perform the rollup.*/
        if (System.isFuture() == false && System.isBatch() == false) {
            summarizeOrderPackagesAsync(OrderLocationIds);
        }
        else {
            new OrderLocationRollupSummary().summarizeOrderPackages(OrderLocationIds);
        }
    }
}

@future
public static void summarizeOrderPackagesAsync(Set<Id> OrderLocationIds) {
    new OrderLocationRollupSummary().summarizeOrderPackages(OrderLocationIds);
}

//Public Methods
public void summarizeOrderPackages(Set<Id> OrderLocationIds) {
    //Get Order Locations to Update
    List<Order_New_Location__c> orderlocations = queryOrderLocationsById(OrderLocationIds);

    Map<Id, AggregateResult> results = getOrderPackagesAmountsByLocationId(OrderLocationIds);

    //Loop Order Locations and set Amounts
    List<Order_New_Location__c> orderlocationsToUpdate = new List<Order_New_Location__c>();
    for (Order_New_Location__c ordloc : orderlocations) {
        double mrf = 0;
        double otf = 0;

        if (results.containsKey(ordloc.Id)) {
            AggregateResult ar = results.get(ordloc.Id);
            mrf = (double)ar.get('MRFees');
            otf = (double)ar.get('OTFees');
        }

        //Determine if Amounts have Changed
        if (ordloc.Package_Monthly_Recurring_Fees__c != mrf || 
            ordloc.Package_One_Time_Fees__c != otf) {
            
            ordloc.Package_Monthly_Recurring_Fees__c = mrf;
            ordloc.Package_One_Time_Fees__c = otf;
            orderlocationsToUpdate.add(ordloc); //Add location to collection to be updated
        }
    }

    if(orderlocationsToUpdate.isEmpty() == false) {
        Database.SaveResult[] saveResults = Database.update(orderlocationsToUpdate, false);
        System.debug(saveResults);
    }
}
//Private Methods
public Map<Id, AggregateResult> getOrderPackagesAmountsByLocationId(Set<Id> OrderLocationIds) {
    Map<id,AggregateResult> resultsByOrderLocationId= new Map<Id,AggregateResult>();

    //Summarize Order Package Amounts by Order Location Id
    AggregateResult[] results = aggregateOrderPackageAmounts(OrderLocationIds);
    for (AggregateResult result : results) {
        Id orderlocationId = (Id) result.get('OrderLocation');
        resultsByOrderLocationId.put(orderlocationId, result );
    }
    return resultsByOrderLocationId;
}

//Query Methods
private List<Order_New_Location__c> queryOrderLocationsById(Set<Id> OrderLocationIds) {
    return [SELECT 
            Id 
            ,Package_Monthly_Recurring_Fees__c
            ,Package_One_Time_Fees__c
        FROM 
            Order_New_Location__c 
        WHERE 
            Id IN :OrderLocationIds];
}

private AggregateResult[] aggregateOrderPackageAmounts(Set<Id> OrderLocationIds) {
    return [SELECT 
             New_Location_Name__c OrderLocation
            ,SUM(Monthly_Recurring_Fees__c) MRFees
            ,SUM(One_Time_Fees__c) OTFees
        FROM 
            Order_Location_Package__c
        WHERE
            New_Location_Name__c IN :OrderLocationIds
        GROUP BY 
            New_Location_Name__c];
}

}

【讨论】：