如何绕过使用 Excel VBA 回复邮件时生成错误的 Outlook 项目？

Question

我有工作代码可以根据主题回复用户 Outlook 中的电子邮件。如果最近的项目是会议邀请，我的代码将无法检索我想要的电子邮件。相反，它不会通过会议邀请并显示错误。

代码如下。

Sub Display()
Dim Fldr As Outlook.Folder
Dim olfolder As Outlook.MAPIFolder
Dim olMail As Outlook.MailItem
Dim olReply As Outlook.MailItem
Dim olItems As Outlook.Items
Dim i As Integer
Dim signature As String


Set Fldr = Session.GetDefaultFolder(olFolderInbox)
Set olItems = Fldr.Items
olItems.Sort "[Received]", True
For i = 1 To olItems.Count
    signature = Environ("appdata") & "\Microsoft\Signatures\"
    If Dir(signature, vbDirectory) <> vbNullString Then
        signature = signature & Dir$(signature & "*.htm")
    Else:
        signature = ""
    End If
    signature = CreateObject("Scripting.FileSystemObject").GetFile(signature).OpenAsTextStream(1, -2).ReadAll

    Set olMail = olItems(i)
    If InStr(olMail.Subject, Worksheets("Checklist Form").Range("B8")) <> 0 Then
        If Not olMail.Categories = "Executed" Then
            Set olReply = olMail.ReplyAll
            With olReply
             .HTMLBody = "<p style='font-family:calibri;font-size:14.5'>" & "Hi Everyone," & "<p style='font-family:calibri;font-size:14.5'>" & "Workflow ID:" & " " & Worksheets("Checklist Form").Range("B6") & "<p style='font-family:calibri;font-size:14.5'>" & Worksheets("Checklist Form").Range("B11") & "<p style='font-family:calibri;font-size:14.5'>" & "Regards," & "</p><br>" & signature & .HTMLBody

             .Display
             .Subject = "RO Finalized WF:" & Worksheets("Checklist Form").Range("B6") & " " & Worksheets("Checklist Form").Range("B2") & " -" & Worksheets("Fulfillment Checklist").Range("B3")
            End With

            Exit For
        olMail.Categories = "Executed"
        End If
    End If
Next i

End Sub

如果代码无法通过第一封电子邮件，是否可以绕过最近的项目。示例：会议邀请

Answer 1

Dim olMail As Outlook.MailItem
...
Set olMail = olItems(i)

Set 分配不仅会在第一个项目是会议邀请时失败，而且对于不是 Outlook.MailItem 实例的任何 olItems(i)（即 i 的任何值）也会失败。这包括任何可能进入 Outlook 收件箱的内容，包括会议邀请。

一种方法是处理在olItems(i) 不是MailItem 的特定情况下引发的运行时错误：

    For i = 1 To olItems.Count
        On Error GoTo ErrHandler ' jumps to error-handling subroutine if there's an error
        Set olMail = olItems(i)
        On Error GoTo 0 ' let any other error blow everything up
        ...
SkipToNext:
    Next i
    Exit Sub
ErrHandler:
    Debug.Print "Item index " & i & " is not a MailItem; skipping."
    Resume SkipToNext

请注意，我会尽早将分配/验证放入循环中 - 这样，如果您没有查看 MailItem，就不会运行无用的指令。

---

另一种更好的方法是验证olItems(i)的类型：

Dim olItem As Object
'...

    For i = 1 To olItems.Count
        Set olItem = olItems(i)
        If Not TypeOf olItem Is Outlook.MailItem Then Goto SkipToNext
        Set olMail = olItem ' essentially a type cast from Object to MailItem
        ...
    SkipToNext:
    Next

或者，您可以放弃 GoTo 跳转并增加嵌套级别：

    For i = 1 To olItems.Count
        Set olItem = olItems(i)
        If TypeOf olItem Is Outlook.MailItem Then
            Set olMail = olItem ' essentially a type cast from Object to MailItem
            ...
        End If
    Next

注意缩进；如果您不确定如何正确且一致地执行此操作，请随时使用indenter。适当的缩进对于代码的可读性至关重要，尤其是考虑到嵌套循环和条件结构（免责声明：我拥有该网站和它所针对的 OSS 项目）。