复制后在原始工作表上选择了目标粘贴范围

Question

嗨，我有一个宏，可以将 Sheet1 中的 H 列复制到 Sheet2 中的 F 列，它可以正常工作，能够复制和粘贴所有值，但是在运行宏后在 Sheet1 中选择了 F 列的范围，并且我不知道为什么或如何补救。下面是我的宏，有什么好的灵魂建议吗？

Sub Button1_Click()
Dim wsCopy As Worksheet
Dim wsDest As Worksheet
Dim lCopyLastRow As Long
Dim lDestLastRow As Long
  Set wsCopy = Worksheets("Sheet1")
  Set wsDest = Worksheets("Sheet2")
    lCopyLastRow = wsCopy.Cells(wsCopy.Rows.Count, "H").End(xlUp).Row
    lDestLastRow = wsDest.Cells(wsDest.Rows.Count, "F").End(xlUp).Offset(1).Row
    wsDest.Range("F2:F" & lDestLastRow).ClearContents
    wsCopy.Range("H7:H" & lCopyLastRow).Copy wsDest.Range("F2")
End Sub

Answer 1

如果您不希望选择 F 列，您可以选择另一个单元格，比如 A1。
这将解决您选择（突出显示）列的问题。

但是，有一种更简洁、更快捷的复制粘贴方法，它在粘贴后也不会选择范围。

只需参考您的范围并使用range1.Value = range2.Value 更改其值，这将仅复制粘贴值。如果您想复制格式、字体大小等，这个想法是相同的。只需使用您要复制/粘贴的任何属性更改 .Value。
在您的情况下，这将使：

Sub Button1_Click()
    Dim wsCopy As Worksheet, wsDest As Worksheet
        Dim lDestLastRow As Long, nbvalues As Long
        
        Set wsCopy = Worksheets("Sheet1")
        Set wsDest = Worksheets("Sheet2")
        
        lDestLastRow = wsDest.Cells(wsDest.Rows.Count, "F").End(xlUp).Offset(1).Row
        
        nbvalues = wsCopy.Range(wsCopy.Range("H7"), wsCopy.Cells(wsCopy.Rows.Count, "H").End(xlUp)).Rows.Count
        wsDest.Range("F2:F" & lDestLastRow).ClearContents
        wsDest.Range("F2:F" & 2 + nbvalues).Value = wsCopy.Range("H7:H" & 7 + nbvalues).Value
End Sub

请注意，对于 VBA 进行复制/粘贴的最后一行，两个范围的长度必须相同，这就是我在源范围和目标范围中使用 lCopyLastRow 的原因。

编辑：为了使用.Value=.Value，两个范围的大小必须相同。 nbvalues 是 Long 表示要粘贴到其他范围内的单元格数，因此 "F2:F" & 2+ nbvalues 是“单元格 F2 到单元格 F（2 + 要粘贴的单元格数）”

Answer 2

.Value=.Value 不会跨格式复制。它只会跨值复制。因此，如果您还想复制其他内容，那么这将无济于事。如果您只想复制值，请选择.Value=.Value 方式。

现在回答你的问题

我不知道为什么或如何补救。

为什么：这没有记录在案的原因。如果您在工作表内复制，那么您将不会看到此问题。仅当您跨工作表复印时才会发生这种情况。事实上，这个Selection 甚至不是一个有效的选择。如果你在复制代码之前和复制代码之后输入Debug.Print Selection.Address，你会注意到它没有给你新选择的范围的地址。

Option Explicit

Sub Sample()
    Debug.Print Selection.Address
    Sheet1.Range("E6:E15").Copy Destination:=Sheet2.Range("M6:M15")
    Debug.Print Selection.Address
End Sub

如何：您可以通过关闭 ScreenUpdating 来摆脱它。

这是一个例子

Sub Sample()
    Application.ScreenUpdating = False
    
    '~~> Sample Copy code
    Sheet1.Range("E6:E15").Copy Destination:=Sheet2.Range("M6:M15")
    
    Application.ScreenUpdating = True
End Sub

或者更好的方式来编写相同的代码

Option Explicit

Sub Sample()
    Dim currentScreenUpdating As Boolean
    
    On Error GoTo Whoa
    
    '~~> Store Users current ScreenUpdating state
    currentScreenUpdating = Application.ScreenUpdating
    
    '~~> Turn off screen updating
    Application.ScreenUpdating = False
    
    '~~> Sample Copy code
    Sheet1.Range("E6:E15").Copy Destination:=Sheet2.Range("M6:M15")
    
LetsContinue:
    '~~> Restore Users ScreenUpdating state
    Application.ScreenUpdating = currentScreenUpdating
    Exit Sub
Whoa:
    MsgBox Err.Description
    Resume LetsContinue
End Sub

行动中

Answer 3

如果在工作表之间切换，所选区域会消失。

尝试添加：

wsDest.Activate
wsCopy.Activate

作为Sub 的最后两行 - 它清除选择。