VBA Excel：删除工作簿中的所有图表和图形，除了一个

Question

我有一个生成大量工作表和图表的宏。还有各种运行的子例程，因此生成的每个工作表/图表的名称和数量永远不会相同。不变的是我的 HOME 工作表，它是用户的 UI，我希望它不受影响。

我在这里发现了一个类似的问题，即删除所有工作表，除了您正在使用的工作表（即 HOME）。这是我目前所拥有的。

Sub ZRESET()

Dim ws As Worksheet, wb As Workbook
Set wb = ActiveWorkbook

    Sheets("HOME").Select

    Application.DisplayAlerts = False
        For Each ws In wb.Worksheets
            If ws.Name <> "HOME" Then
                ws.Delete
            End If
            If Chart.Name = "" Then
                Charts.Delete
            End If
        Next
    Application.DisplayAlerts = True

    Range("B5:E5,B9:E9,B13:E13,B14:E14").ClearContents
    Range("A1").Select

End Sub

工作表删除得很好，我挂断的是图表。我尝试了各种删除图表的尝试，有时它们会起作用（即将 Charts.Delete 放在 FOR 循环和 IF 语句之外）。但这需要我在工作簿中实际有一个图表。有时用户可以只开发工作表，但不能开发图表。

有什么建议可以继续我的目标，即删除 SHEETS 和/或 CHARTS，同时保持我的 HOME 表完好无损？

Answer 1

Option Explicit

Sub GetRid()
  Dim ASheet As Worksheet
  Dim AChart As Chart


  Application.DisplayAlerts = False
  Application.ScreenUpdating = False

  '** first scan for and delete all non HOME worksheets ***
  For Each ASheet In ActiveWorkbook.Worksheets
    If UCase(ASheet.Name) <> "HOME" Then
      ASheet.Delete
    End If
  Next

  '** Now scan and delete any ChartSheets ****
  For Each AChart In ActiveWorkbook.Charts
    AChart.Delete
  Next

  Application.DisplayAlerts = True
  Application.ScreenUpdating = True

End Sub

Answer 2

Option Explicit

Sub AllSheetsAndcharts()

  Dim AChart As ChartObject
  Dim ASheet As Worksheet
  Application.DisplayAlerts = False
  For Each ASheet In ActiveWorkbook.Worksheets
     If UCase(ASheet.Name) <> "HOME" Then

       For Each AChart In ASheet.ChartObjects
         AChart.Delete
       Next
       ASheet.Delete
     End If
  Next
  Application.DisplayAlerts = False

End Sub